# Analyze MCP server tool calls telemetry
APPLIES TO: Business Central 2026 release wave 1, version 28.0, and later
Model Context Protocol (MCP)<../ai/mcp-overview> server telemetry gathers data about calls that external MCP hosts make to tools exposed by Business Central MCP server configurations. This telemetry helps you understand how external clients use Business Central through MCP.
See Configure Business Central MCP Server<../ai/configure-mcp-server>.
## MCP server tool called
Occurs when Business Central processes a tool call from an MCP host.
### General dimensions
Dimension|Description or value
message|MCP Server tool called: '{toolName}'
user_Id|The user telemetry ID for the user. From the user card, you can use user_Id to identify the user who triggered this telemetry event. See telemetry-enable-application-insights#assign-a-telemetry-id-to-users.
### Custom dimensions
Dimension|Description or value
aadTenantId|Specifies the Microsoft Entra tenant ID used for Microsoft Entra authentication. For on-premises, if you aren't using Microsoft Entra authentication, this value is common.
companyName|The current company name.
environmentName|Specifies the name of the tenant environment. See Managing Environments<tenant-admin-center-environments>.
environmentType|Specifies the environment type for the tenant, such as Production or Sandbox. See tenant-admin-center-environments#types-of-environments.
eventId|RT0054
configurationName|Specifies the name of the MCP configuration that was used for the tool call.
configurationSystemId|Specifies the system ID (GUID) of the MCP configuration record.
toolName|Specifies the name of the MCP tool that was called.
dynamicToolName|Specifies the action name for dynamic MCP tools. This dimension is populated when using dynamic tool configurations.
clientName|Specifies the name of the MCP host that initiated the tool call.
authAppId|Specifies the authenticated application ID from the security token.
result|Specifies the result of the operation. Possible values are Success or Failure.
totalTime|Specifies the total time the operation ran for.
serverExecutionTime|Specifies the amount of time the operation took on server. The time has the format hh:mm:ss.sssssss.
toolInvocationResult|Specifies the result of the MCP tool invocation. Possible values are Success or Failure. This dimension can be absent if an exception prevents the tool call from returning a result.
toolInvocationFailureReason|Specifies the reason for the tool invocation failure. This dimension is only populated when toolInvocationResult is Failure.
### Sample KQL code
This KQL code can help you get started analyzing MCP Server tool calls:
```kql
traces
| where timestamp > ago(60d) // adjust as needed
| where customDimensions.eventId == 'RT0054'
| project timestamp
, aadTenantId = customDimensions.aadTenantId
, environmentName = customDimensions.environmentName
, environmentType = customDimensions.environmentType
, companyName = customDimensions.companyName
, configurationName = customDimensions.configurationName
, toolName = customDimensions.toolName
, dynamicToolName = customDimensions.dynamicToolName
, clientName = customDimensions.clientName
, toolInvocationResult = customDimensions.toolInvocationResult
, toolInvocationFailureReason = customDimensions.toolInvocationFailureReason
, totalTime = customDimensions.totalTime
, serverExecutionTime = customDimensions.serverExecutionTime
```
### Sample KQL code for failed tool invocations
This KQL code can help you analyze failed MCP Server tool calls:
```kql
traces
| where timestamp > ago(60d) // adjust as needed
| where customDimensions.eventId == 'RT0054'
| where customDimensions.toolInvocationResult == 'Failure'
| project timestamp
, aadTenantId = customDimensions.aadTenantId
, environmentName = customDimensions.environmentName
, environmentType = customDimensions.environmentType
, companyName = customDimensions.companyName
, configurationName = customDimensions.configurationName
, toolName = customDimensions.toolName
, clientName = customDimensions.clientName
, toolInvocationFailureReason = customDimensions.toolInvocationFailureReason
| summarize FailureCount = count() by tostring(toolName), tostring(toolInvocationFailureReason)
| order by FailureCount desc
```
### Sample KQL code for tool usage by configuration
This KQL code can help you understand which MCP configurations and tools are being used most frequently:
```kql
traces
| where timestamp > ago(30d) // adjust as needed
| where customDimensions.eventId == 'RT0054'
| summarize
    TotalCalls = count()
  , SuccessfulCalls = countif(customDimensions.toolInvocationResult == 'Success')
  , FailedCalls = countif(customDimensions.toolInvocationResult == 'Failure')
  , AvgServerExecutionTimeInMs = avg(toreal(totimespan(customDimensions.serverExecutionTime)) / 10000)
  by
    ConfigurationName = tostring(customDimensions.configurationName)
  , ToolName = tostring(customDimensions.toolName)
  , ClientName = tostring(customDimensions.clientName)
| extend SuccessRate = round(100.0 * SuccessfulCalls / TotalCalls, 2)
| order by TotalCalls desc
```
To learn more about how to set up alerting on Business Central telemetry, see telemetry-alert.
## Related information
Model Context Protocol (MCP) in Business Central overview<../ai/mcp-overview>
Configure Business Central MCP Server<../ai/configure-mcp-server>
Connect to Business Central MCP Server with Visual Studio Code<../ai/use-mcp-server-in-vscode>
Connect to Business Central MCP server with non-Microsoft clients<../ai/use-mcp-server-non-microsoft>
Business Central Admin Center API MCP server<administration-center-api-mcp>
Monitoring and Analyzing Telemetry<telemetry-overview>
Enable Sending Telemetry to Application Insights<telemetry-enable-application-insights>
telemetry-alert

Copyright (c) Microsoft Corporation. CC BY 4.0, https://creativecommons.org/licenses/by/4.0/; code samples MIT. From https://learn.microsoft.com/en-us/dynamics365/business-central/dev-itpro/administration/telemetry-mcp-server-trace, MicrosoftDocs/dynamics365smb-devitpro-pb at 828b6ee (2026-11-19). Changed: includes filled in, links to this site, and for agents shortened without dropping a fact. https://jonas-paprotka.de/docs/dev-itpro/administration/telemetry-mcp-server-trace/
