# Working with ListPart pages
A ListPart page is a type of page part used to display a list of records embedded within another page. It consists of a repeater control, which presents the records of the source table as rows and columns, and optionally, of an action bar.
A list part can be contained in Role Centers, in the FactBox and content area of other pages, in a tabular step in a wizard, and as a subpage in a document page. Depending on the type of the hosting page, a list part is subject to different design constraints, which determine its position and dimensions. See devenv-designing-parts#design-considerations.
## Creating a list part
To create a list part, you start by creating a page object, set the properties/devenv-pagetype-property to ListPart, and then specify the source table. A list part page uses a single repeater control, located inside `area(Content)`, where you specify the field controls that you want to display. The structure is similar to that of a List page, except that there isn't any FactBox section, because part pages can't host other parts. See List page structure<devenv-designing-list-pages?tabs=structure#structure-1>.
## Adding a list part to a page
To place the list part in a page, you add a part control to the hosting page and associate it with the list part page object that you created. Here you can also define more properties. These only apply to the container of the list part, whose functionality is independent from the hosting page.
## Example
The following code sample illustrates how to create a ListPart page, `"Pending Shipments"`, and how to integrate it in the card page `"Customer Card"`.
```al
page 50101 "Pending Shipments"
{
    PageType = ListPart;
    SourceTable = "Sales Header";
    // Filter on the sales orders that are pending completion.
    SourceTableView = WHERE("Completely Shipped" = CONST(False));

    layout
    {
        area(Content)
        {
            repeater(General)
            {
                field("No."; "No.")
                {
                    ApplicationArea = All;
                }
                field("Order Date"; "Order Date")
                {
                    ApplicationArea = All;
                }
                field("Location Code"; "Location Code")
                {
                    ApplicationArea = All;
                }
            }
        }
    }
}

page 50102 "Customer Card"
{
    PageType = Card;
    SourceTable = Customer;

    layout
    {
        area(Content)
        {
            group(General)
            {
                field("No."; "No.")
                {
                    ApplicationArea = All;
                }
                field(Name; Name)
                {
                    ApplicationArea = All;
                }
            }
            group(Shipments)
            {
                part("Pending Shipments"; "Pending Shipments")
                {
                    // Filter on the sales orders that relate to the customer in the card page.
                    SubPageLink = "Sell-to Customer No." = FIELD("No.");
                }
            }
        }
    }
}
```
## Related information
Page parts overview<devenv-designing-parts>
devenv-page-types-and-layouts
devenv-designing-list-pages
devenv-page-object
Page extension object<devenv-page-ext-object>
devenv-adding-a-factbox-to-page
CardPart pages<devenv-designing-cardparts>
AL development environment<devenv-reference-overview>
Use Designer<devenv-inclient-designer>

Copyright (c) Microsoft Corporation. CC BY 4.0, https://creativecommons.org/licenses/by/4.0/; code samples MIT. From https://learn.microsoft.com/en-us/dynamics365/business-central/dev-itpro/developer/devenv-designing-listparts, MicrosoftDocs/dynamics365smb-devitpro-pb at 828b6ee (2026-11-19). Changed: includes filled in, links to this site, and for agents shortened without dropping a fact. https://jonas-paprotka.de/docs/dev-itpro/developer/devenv-designing-listparts/
