Codeunit 5004 Sales Shipment PDF Doc.Handler, source in 29

// ------------------------------------------------------------------------------------------------
// Copyright (c) Microsoft Corporation. All rights reserved.
// Licensed under the MIT License. See License.txt in the project root for license information.
// ------------------------------------------------------------------------------------------------
namespace Microsoft.EServices.EDocument;

using Microsoft.Foundation.Reporting;
using Microsoft.Integration.Graph;
using Microsoft.Sales.History;
using System.EMail;
using System.Utilities;

codeunit 5004 "Sales Shipment PDF Doc.Handler" implements IPdfDocumentHandler
{
    var
        SalesShipmentLbl: Label 'Sales Shipment';

    /// <summary>
    /// Generates a PDF blob for Blanket Sales Order
    /// </summary>
    /// <param name="DocumentId">Document ID</param>
    /// <param name="DocumentType">Document Type</param>
    /// <param name="TempAttachmentEntityBuffer">The buffer to store successfully generated report</param>
    /// <returns>True if the generated report successfully added to the buffer, otherwise false.</returns>    
    procedure GeneratePdfBlobWithDocumentType(DocumentId: Guid; DocumentType: Enum "Attachment Entity Buffer Document Type"; var TempAttachmentEntityBuffer: Record "Attachment Entity Buffer" temporary): Boolean
    var
        SalesShptHeader: Record "Sales Shipment Header";
        ReportSelections: Record "Report Selections";
        DocumentMailing: Codeunit "Document-Mailing";
        PDFDocumentManagement: Codeunit "PDF Document Management";
        TempBlob: Codeunit "Temp Blob";
        Name: Text[250];
        ReportUsage: Enum "Report Selection Usage";
    begin
        if not SalesShptHeader.GetBySystemId(DocumentId) then
            exit(false);

        SalesShptHeader.SetRange("No.", SalesShptHeader."No.");
        ReportUsage := "Report Selection Usage"::"S.Shipment";
        ReportSelections.GetPdfReportForCust(TempBlob, ReportUsage, SalesShptHeader, SalesShptHeader."Bill-to Customer No.");
        DocumentMailing.GetAttachmentFileName(Name, SalesShptHeader."No.", SalesShipmentLbl, ReportUsage.AsInteger());
        exit(PDFDocumentManagement.AddToTempAttachmentEntityBuffer(DocumentId, DocumentType, TempBlob, Name, TempAttachmentEntityBuffer));
    end;
}