Page 5780 Whse. Pick Subform, source in 29
Source29
src/Layers/W1/BaseApp/Warehouse/Activity/WhsePickSubform.Page.al633 lines, Copyright (c) Microsoft Corporation. MIT
// ------------------------------------------------------------------------------------------------
// Copyright (c) Microsoft Corporation. All rights reserved.
// Licensed under the MIT License. See License.txt in the project root for license information.
// ------------------------------------------------------------------------------------------------
namespace Microsoft.Warehouse.Activity;
using Microsoft.Inventory.Availability;
using Microsoft.Inventory.Location;
using Microsoft.Warehouse.Availability;
using Microsoft.Warehouse.Journal;
using Microsoft.Warehouse.Structure;
page 5780 "Whse. Pick Subform"
{
AutoSplitKey = true;
Caption = 'Lines';
DelayedInsert = true;
InsertAllowed = false;
LinksAllowed = false;
MultipleNewLines = true;
PageType = ListPart;
SourceTable = "Warehouse Activity Line";
SourceTableView = where("Activity Type" = const(Pick));
layout
{
area(content)
{
repeater(Control1)
{
ShowCaption = false;
field("Action Type"; Rec."Action Type")
{
ApplicationArea = Warehouse;
Visible = not HideBinFields;
}
field("Item No."; Rec."Item No.")
{
ApplicationArea = Warehouse;
}
field("Variant Code"; Rec."Variant Code")
{
ApplicationArea = Planning;
Visible = false;
}
field(Description; Rec.Description)
{
ApplicationArea = Warehouse;
}
field("Serial No."; Rec."Serial No.")
{
ApplicationArea = ItemTracking;
Visible = false;
trigger OnValidate()
begin
SerialNoOnAfterValidate();
end;
}
field("Serial No. Blocked"; Rec."Serial No. Blocked")
{
ApplicationArea = ItemTracking;
Visible = false;
}
field("Lot No."; Rec."Lot No.")
{
ApplicationArea = ItemTracking;
Visible = false;
trigger OnValidate()
begin
LotNoOnAfterValidate();
end;
}
field("Lot No. Blocked"; Rec."Lot No. Blocked")
{
ApplicationArea = ItemTracking;
Visible = false;
}
field("Package No."; Rec."Package No.")
{
ApplicationArea = ItemTracking;
Visible = false;
}
field("Expiration Date"; Rec."Expiration Date")
{
ApplicationArea = ItemTracking;
Editable = false;
Visible = false;
}
field("Location Code"; Rec."Location Code")
{
ApplicationArea = Location;
Visible = false;
}
field("Zone Code"; Rec."Zone Code")
{
ApplicationArea = Warehouse;
Editable = ZoneCodeEditable;
Visible = false;
}
field("Bin Code"; Rec."Bin Code")
{
ApplicationArea = Warehouse;
Editable = BinCodeEditable;
Visible = not HideBinFields;
trigger OnValidate()
begin
BinCodeOnAfterValidate();
end;
}
field("Shelf No."; Rec."Shelf No.")
{
ApplicationArea = Warehouse;
Visible = false;
}
field(Quantity; Rec.Quantity)
{
ApplicationArea = Warehouse;
Editable = (Rec."Activity Type" = Rec."Activity Type"::Pick) and (Rec."Source Document" = Rec."Source Document"::"Prod. Consumption") and (Rec."Action Type" = Rec."Action Type"::Take);
}
field("Qty. (Base)"; Rec."Qty. (Base)")
{
ApplicationArea = Warehouse;
ToolTip = 'Specifies the quantity of the item to be handled, in the base unit of measure.';
Visible = false;
}
field("Qty. to Handle"; Rec."Qty. to Handle")
{
ApplicationArea = Warehouse;
trigger OnValidate()
begin
QtytoHandleOnAfterValidate();
end;
}
field("Qty. Handled"; Rec."Qty. Handled")
{
ApplicationArea = Warehouse;
Visible = true;
}
field("Qty. to Handle (Base)"; Rec."Qty. to Handle (Base)")
{
ApplicationArea = Warehouse;
ToolTip = 'Specifies the quantity of items to be handled in this warehouse activity.';
Visible = false;
}
field("Qty. Handled (Base)"; Rec."Qty. Handled (Base)")
{
ApplicationArea = Warehouse;
ToolTip = 'Specifies the number of items on the line that have been handled in this warehouse activity.';
Visible = false;
}
field("Qty. Outstanding"; Rec."Qty. Outstanding")
{
ApplicationArea = Warehouse;
Visible = true;
}
field("Qty. Outstanding (Base)"; Rec."Qty. Outstanding (Base)")
{
ApplicationArea = Warehouse;
ToolTip = 'Specifies the number of items, expressed in the base unit of measure, that have not yet been handled for this warehouse activity line.';
Visible = false;
}
field("Due Date"; Rec."Due Date")
{
ApplicationArea = Warehouse;
}
field("Unit of Measure Code"; Rec."Unit of Measure Code")
{
ApplicationArea = Suite;
}
field("Qty. per Unit of Measure"; Rec."Qty. per Unit of Measure")
{
ApplicationArea = Suite;
}
field("Shipping Advice"; Rec."Shipping Advice")
{
ApplicationArea = Warehouse;
Visible = false;
}
field("Destination Type"; Rec."Destination Type")
{
ApplicationArea = Warehouse;
}
field("Source Document"; Rec."Source Document")
{
ApplicationArea = Warehouse;
BlankZero = true;
}
field("Source No."; Rec."Source No.")
{
ApplicationArea = Warehouse;
}
field("Destination No."; Rec."Destination No.")
{
ApplicationArea = Warehouse;
}
field("Shipping Agent Code"; Rec."Shipping Agent Code")
{
ApplicationArea = Warehouse;
Visible = false;
}
field("Shipping Agent Service Code"; Rec."Shipping Agent Service Code")
{
ApplicationArea = Warehouse;
Visible = false;
}
field("Shipment Method Code"; Rec."Shipment Method Code")
{
ApplicationArea = Warehouse;
Visible = false;
}
field("Whse. Document Type"; Rec."Whse. Document Type")
{
ApplicationArea = Warehouse;
Visible = false;
}
field("Whse. Document No."; Rec."Whse. Document No.")
{
ApplicationArea = Warehouse;
Visible = false;
}
field("Whse. Document Line No."; Rec."Whse. Document Line No.")
{
ApplicationArea = Warehouse;
Visible = false;
}
field("Special Equipment Code"; Rec."Special Equipment Code")
{
ApplicationArea = Warehouse;
Visible = false;
}
field("Assemble to Order"; Rec."Assemble to Order")
{
ApplicationArea = Assembly;
Visible = false;
}
}
}
}
actions
{
area(processing)
{
group("F&unctions")
{
Caption = 'F&unctions';
Image = "Action";
action(SplitWhseActivityLine)
{
ApplicationArea = Warehouse;
Caption = '&Split Line';
Image = Split;
ShortCutKey = 'Ctrl+F11';
ToolTip = 'Enable that the items can be taken or placed in more than one bin, for example, because the quantity in the suggested bin is insufficient to pick or move or there is not enough room to put away the required quantity.';
trigger OnAction()
var
WhseActivLine: Record "Warehouse Activity Line";
begin
WhseActivLine.Copy(Rec);
Rec.SplitLine(WhseActivLine);
Rec.Copy(WhseActivLine);
CurrPage.Update(false);
end;
}
action(FillQtyToHandle)
{
ApplicationArea = Warehouse;
Caption = 'Autofill Qty. To Handle';
Image = AutofillQtyToHandle;
Gesture = LeftSwipe;
ToolTip = 'Have the system enter the outstanding quantity in the Qty. to Handle field.';
Scope = Repeater;
trigger OnAction()
begin
Rec.AutofillQtyToHandleOnLine(Rec);
end;
}
action(ResetQtyToHandle)
{
ApplicationArea = Warehouse;
Caption = 'Reset Qty. To Handle';
Image = UndoFluent;
Gesture = RightSwipe;
ToolTip = 'Have the system clear the value in the Qty. To Handle field.';
Scope = Repeater;
trigger OnAction()
begin
Rec.DeleteQtyToHandleOnLine(Rec);
end;
}
action(ChangeUnitOfMeasure)
{
ApplicationArea = Warehouse;
Caption = '&Change Unit Of Measure';
Ellipsis = true;
Image = UnitConversions;
ToolTip = 'Specify which unit of measure you want to change during the warehouse activity, for example, because you want to ship an item in boxes although you store it in pallets.';
trigger OnAction()
begin
ChangeUOM();
end;
}
action(Scan)
{
ApplicationArea = Warehouse;
Caption = 'Scan';
Ellipsis = true;
Image = BarCode;
ToolTip = 'Scan the items on this line.';
RunObject = Page "Scan Warehouse Activity Line";
RunPageLink = "No." = field("No.");
RunPageView = sorting("Activity Type", "No.", "Sorting Sequence No.");
}
}
group("&Line")
{
Caption = '&Line';
Image = Line;
action("Source &Document Line")
{
ApplicationArea = Warehouse;
Caption = 'Source &Document Line';
Image = SourceDocLine;
ToolTip = 'View the line on a released source document that the warehouse activity is for. ';
trigger OnAction()
begin
ShowSourceLine();
end;
}
action("Whse. Document Line")
{
ApplicationArea = Warehouse;
Caption = 'Whse. Document Line';
Image = Line;
ToolTip = 'View the line on another warehouse document that the warehouse activity is for.';
trigger OnAction()
begin
WMSMgt.ShowWhseActivityDocLine(
Rec."Whse. Document Type", Rec."Whse. Document No.", Rec."Whse. Document Line No.");
end;
}
action("Bin Contents List")
{
ApplicationArea = Warehouse;
Caption = 'Bin Contents List';
Image = BinContent;
ToolTip = 'View the contents of the selected bin and the parameters that define how items are routed through the bin.';
trigger OnAction()
begin
ShowBinContents();
end;
}
group("Item Availability by")
{
Caption = 'Item Availability by';
Image = ItemAvailability;
action("Event")
{
ApplicationArea = Warehouse;
Caption = 'Event';
Image = "Event";
ToolTip = 'View how the actual and the projected available balance of an item will develop over time according to supply and demand events.';
trigger OnAction()
begin
ItemAvailability("Item Availability Type"::"Event");
end;
}
action(Period)
{
ApplicationArea = Warehouse;
Caption = 'Period';
Image = Period;
ToolTip = 'View the projected quantity of the item over time according to time periods, such as day, week, or month.';
trigger OnAction()
begin
ItemAvailability("Item Availability Type"::Period);
end;
}
action(Variant)
{
ApplicationArea = Planning;
Caption = 'Variant';
Image = ItemVariant;
ToolTip = 'View or edit the item''s variants. Instead of setting up each color of an item as a separate item, you can set up the various colors as variants of the item.';
trigger OnAction()
begin
ItemAvailability("Item Availability Type"::Variant);
end;
}
action(Location)
{
AccessByPermission = TableData Location = R;
ApplicationArea = Warehouse;
Caption = 'Location';
Image = Warehouse;
ToolTip = 'View the actual and projected quantity of the item per location.';
trigger OnAction()
begin
ItemAvailability("Item Availability Type"::Location);
end;
}
action(Lot)
{
ApplicationArea = ItemTracking;
Caption = 'Lot';
Image = LotInfo;
RunObject = Page "Item Availability by Lot No.";
RunPageLink = "No." = field("Item No."),
"Location Filter" = field("Location Code"),
"Variant Filter" = field("Variant Code");
ToolTip = 'View the current and projected quantity of the item in each lot.';
}
}
}
}
}
trigger OnAfterGetCurrRecord()
begin
EnableZoneBin();
end;
trigger OnDeleteRecord(): Boolean
begin
CurrPage.Update(false);
end;
trigger OnInit()
begin
BinCodeEditable := true;
ZoneCodeEditable := true;
end;
trigger OnNewRecord(BelowxRec: Boolean)
begin
Rec."Activity Type" := xRec."Activity Type";
end;
trigger OnOpenPage()
begin
end;
var
WarehouseAvailabilityMgt: Codeunit "Warehouse Availability Mgt.";
WMSMgt: Codeunit "WMS Management";
ZoneCodeEditable: Boolean;
BinCodeEditable: Boolean;
HideBinFields: Boolean;
local procedure ShowSourceLine()
begin
WMSMgt.ShowSourceDocLine(
Rec."Source Type", Rec."Source Subtype", Rec."Source No.", Rec."Source Line No.", Rec."Source Subline No.");
end;
local procedure ItemAvailability(AvailabilityType: Enum "Item Availability Type")
begin
WarehouseAvailabilityMgt.ShowItemAvailabilityFromWhseActivLine(Rec, AvailabilityType);
end;
internal procedure SetHideBinFields(NewHideBinFields: Boolean)
begin
HideBinFields := NewHideBinFields;
end;
procedure AutofillQtyToHandle()
var
WhseActivLine: Record "Warehouse Activity Line";
begin
WhseActivLine.Copy(Rec);
WhseActivLine.SetRange("Activity Type", Rec."Activity Type");
WhseActivLine.SetRange("No.", Rec."No.");
OnAutofillQtyToHandleOnBeforeRecAutofillQtyToHandle(WhseActivLine);
Rec.AutofillQtyToHandle(WhseActivLine);
end;
procedure DeleteQtyToHandle()
var
WhseActivLine: Record "Warehouse Activity Line";
begin
WhseActivLine.Copy(Rec);
WhseActivLine.SetRange("Activity Type", Rec."Activity Type");
WhseActivLine.SetRange("No.", Rec."No.");
Rec.DeleteQtyToHandle(WhseActivLine);
end;
local procedure ChangeUOM()
var
WhseActLine: Record "Warehouse Activity Line";
WhseChangeOUM: Report "Whse. Change Unit of Measure";
begin
Rec.TestField("Action Type");
Rec.TestField("Breakbulk No.", 0);
Rec.TestField("Action Type", 1);
WhseChangeOUM.DefWhseActLine(Rec);
WhseChangeOUM.RunModal();
if WhseChangeOUM.ChangeUOMCode(WhseActLine) then
Rec.ChangeUOMCode(Rec, WhseActLine);
Clear(WhseChangeOUM);
CurrPage.Update(false);
end;
procedure RegisterActivityYesNo()
var
WhseActivLine: Record "Warehouse Activity Line";
IsHandled: Boolean;
begin
IsHandled := false;
OnBeforeRegisterActivityYesNo(Rec, IsHandled);
if IsHandled then
exit;
WhseActivLine.Copy(Rec);
WhseActivLine.SetCurrentKey("Activity Type", "No.", "Sorting Sequence No.");
WhseActivLine.FilterGroup(3);
WhseActivLine.SetRange(Breakbulk);
WhseActivLine.FilterGroup(0);
CODEUNIT.Run(CODEUNIT::"Whse.-Act.-Register (Yes/No)", WhseActivLine);
Rec.Reset();
Rec.SetCurrentKey("Activity Type", "No.", "Sorting Sequence No.");
Rec.FilterGroup(4);
Rec.SetRange("Activity Type", Rec."Activity Type");
Rec.SetRange("No.", Rec."No.");
Rec.FilterGroup(3);
Rec.SetRange(Breakbulk, false);
Rec.FilterGroup(0);
CurrPage.Update(false);
OnAfterRegisterActivityYesNo(Rec);
end;
local procedure ShowBinContents()
var
BinContent: Record "Bin Content";
begin
BinContent.ShowBinContents(Rec."Location Code", Rec."Item No.", Rec."Variant Code", '')
end;
local procedure EnableZoneBin()
var
PlaceLineForConsumption: Boolean;
begin
PlaceLineForConsumption :=
(Rec."Action Type" = Rec."Action Type"::Place) and
(Rec."Source Document" in ["Warehouse Activity Source Document"::"Prod. Consumption",
"Warehouse Activity Source Document"::"Assembly Consumption",
"Warehouse Activity Source Document"::"Job Usage"]) and
(Rec."Whse. Document Type" in ["Warehouse Activity Document Type"::Production,
"Warehouse Activity Document Type"::Assembly,
"Warehouse Activity Document Type"::Job]);
ZoneCodeEditable :=
(Rec."Action Type" = Rec."Action Type"::Take) or (Rec."Breakbulk No." <> 0) or PlaceLineForConsumption;
BinCodeEditable :=
(Rec."Action Type" = Rec."Action Type"::Take) or (Rec."Breakbulk No." <> 0) or PlaceLineForConsumption;
end;
local procedure SerialNoOnAfterValidate()
var
IsHandled: Boolean;
begin
IsHandled := false;
OnBeforeSerialNoOnAfterValidate(Rec, IsHandled);
if IsHandled then
exit;
Rec.UpdateExpirationDate(Rec.FieldNo("Serial No."));
end;
local procedure LotNoOnAfterValidate()
var
IsHandled: Boolean;
begin
IsHandled := false;
OnBeforeLotNoOnAfterValidate(Rec, IsHandled);
if IsHandled then
exit;
Rec.UpdateExpirationDate(Rec.FieldNo("Lot No."));
end;
protected procedure BinCodeOnAfterValidate()
begin
CurrPage.Update();
end;
protected procedure QtytoHandleOnAfterValidate()
begin
CurrPage.SaveRecord();
end;
[IntegrationEvent(false, false)]
local procedure OnAutofillQtyToHandleOnBeforeRecAutofillQtyToHandle(var WarehouseActivityLine: Record "Warehouse Activity Line")
begin
end;
[IntegrationEvent(false, false)]
local procedure OnBeforeLotNoOnAfterValidate(var Rec: Record "Warehouse Activity Line"; var IsHandled: Boolean)
begin
end;
[IntegrationEvent(false, false)]
local procedure OnBeforeSerialNoOnAfterValidate(var Rec: Record "Warehouse Activity Line"; var IsHandled: Boolean)
begin
end;
[IntegrationEvent(false, false)]
local procedure OnBeforeRegisterActivityYesNo(var WarehouseActivityLine: Record "Warehouse Activity Line"; var IsHandled: Boolean)
begin
end;
[IntegrationEvent(false, false)]
local procedure OnAfterRegisterActivityYesNo(var WarehouseActivityLine: Record "Warehouse Activity Line")
begin
end;
}