Page 99000823 Output Journal, source in 29
Source29
src/Layers/W1/BaseApp/Manufacturing/Journal/OutputJournal.Page.al1234 lines, Copyright (c) Microsoft Corporation. MIT
// ------------------------------------------------------------------------------------------------
// Copyright (c) Microsoft Corporation. All rights reserved.
// Licensed under the MIT License. See License.txt in the project root for license information.
// ------------------------------------------------------------------------------------------------
namespace Microsoft.Manufacturing.Journal;
using Microsoft.Finance.Dimension;
using Microsoft.Foundation.Reporting;
using Microsoft.Inventory.Item;
using Microsoft.Inventory.Item.Catalog;
using Microsoft.Inventory.Journal;
using Microsoft.Inventory.Ledger;
using Microsoft.Inventory.Tracking;
using Microsoft.Manufacturing.Capacity;
using Microsoft.Manufacturing.Document;
using Microsoft.Utilities;
using Microsoft.Warehouse.Structure;
using System.Automation;
using System.Environment;
using System.Environment.Configuration;
using System.Integration;
using System.Privacy;
page 99000823 "Output Journal"
{
ApplicationArea = Manufacturing;
AutoSplitKey = true;
Caption = 'Output Journals';
DataCaptionFields = "Journal Batch Name";
DelayedInsert = true;
PageType = Worksheet;
AboutTitle = 'About Output Journals';
AboutText = 'Record and post output quantities, run times, and completion status for production order operations, updating inventory and capacity ledgers as manufacturing progresses. Use functions to generate journal lines from production orders, mark operations as finished, and preview entries before posting.';
SaveValues = true;
SourceTable = "Item Journal Line";
UsageCategory = Tasks;
layout
{
area(content)
{
group(Control120)
{
ShowCaption = false;
field(CurrentJnlBatchName; CurrentJnlBatchName)
{
ApplicationArea = Manufacturing;
Caption = 'Batch Name';
Lookup = true;
ToolTip = 'Specifies the name of the journal batch, a personalized journal layout, that the journal is based on.';
trigger OnLookup(var Text: Text): Boolean
begin
CurrPage.SaveRecord();
ItemJnlMgt.LookupName(CurrentJnlBatchName, Rec);
SetControlAppearanceFromBatch();
CurrPage.Update(false);
ItemJnlMgt.CheckName(CurrentJnlBatchName, Rec);
end;
trigger OnValidate()
begin
ItemJnlMgt.CheckName(CurrentJnlBatchName, Rec);
CurrentJnlBatchNameOnAfterValidate();
end;
}
field(ItemJnlBatchApprovalStatus; ItemJnlBatchApprovalStatus)
{
ApplicationArea = Manufacturing;
Caption = 'Approval Status';
Editable = false;
Visible = EnabledItemJnlBatchWorkflowsExist;
ToolTip = 'Specifies the approval status for output journal batch.';
}
}
repeater(Control1)
{
ShowCaption = false;
field("Posting Date"; Rec."Posting Date")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the posting date for the entry.';
}
field("Order No."; Rec."Order No.")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the number of the order that created the entry.';
trigger OnValidate()
begin
MfgItemJournalMgt.GetOutput(Rec, ProdOrderDescription, OperationName);
end;
}
field("Document No."; Rec."Document No.")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies a document number for the journal line.';
ShowMandatory = true;
}
field("Item No."; Rec."Item No.")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the number of the item on the journal line.';
trigger OnLookup(var Text: Text): Boolean
begin
Rec.LookupItemNo();
Rec.ShowShortcutDimCode(ShortcutDimCode);
end;
trigger OnValidate()
begin
ItemNoOnAfterValidate();
end;
}
field("Item Reference No."; Rec."Item Reference No.")
{
AccessByPermission = tabledata "Item Reference" = R;
ApplicationArea = Manufacturing, ItemReferences;
QuickEntry = false;
ToolTip = 'Specifies a reference to the item number as defined by the item''s barcode.';
Visible = false;
trigger OnLookup(var Text: Text): Boolean
var
ItemReferenceManagement: Codeunit "Item Reference Management";
begin
ItemReferenceManagement.ItemJournalReferenceNoLookup(Rec);
ItemNoOnAfterValidate();
OnReferenceNoOnAfterLookup(Rec);
end;
trigger OnValidate()
begin
ItemNoOnAfterValidate();
end;
}
field("Operation No."; Rec."Operation No.")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the number of the production operation on the item journal line when the journal functions as an output journal.';
trigger OnValidate()
begin
MfgItemJournalMgt.GetOutput(Rec, ProdOrderDescription, OperationName);
end;
}
field("Order Line No."; Rec."Order Line No.")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the line number of the order that created the entry.';
}
field(Type; Rec.Type)
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the journal type, which is either Work Center or Machine Center.';
}
field("No."; Rec."No.")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the number of the involved entry or record, according to the specified number series.';
}
field("Variant Code"; Rec."Variant Code")
{
ApplicationArea = Planning;
ToolTip = 'Specifies the variant of the item on the line.';
Visible = false;
}
field(Description; Rec.Description)
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies a description of the item on the journal line.';
}
field("Work Shift Code"; Rec."Work Shift Code")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the work shift code for this Journal line.';
Visible = false;
}
field("Gen. Bus. Posting Group"; Rec."Gen. Bus. Posting Group")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the vendor''s or customer''s trade type to link transactions made for this business partner with the appropriate general ledger account according to the general posting setup.';
Visible = false;
}
field("Gen. Prod. Posting Group"; Rec."Gen. Prod. Posting Group")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the item''s product type to link transactions made for this item with the appropriate general ledger account according to the general posting setup.';
Visible = false;
}
field("Starting Time"; Rec."Starting Time")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the starting time of the operation on the item journal line.';
Visible = false;
}
field("Ending Time"; Rec."Ending Time")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the ending time of the operation on the item journal line.';
Visible = false;
}
field("Concurrent Capacity"; Rec."Concurrent Capacity")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the concurrent capacity.';
Visible = false;
}
field("Setup Time"; Rec."Setup Time")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the time required to set up the machines for this journal line.';
Visible = false;
}
field("Run Time"; Rec."Run Time")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the run time of the operations represented by this journal line.';
}
field("Cap. Unit of Measure Code"; Rec."Cap. Unit of Measure Code")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the unit of measure code for the capacity usage.';
}
field("Unit Cost"; Rec."Unit Cost")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the cost of one unit of the item or resource on the line.';
Visible = false;
}
field("Location Code"; Rec."Location Code")
{
ApplicationArea = Location;
ToolTip = 'Specifies the code for the inventory location where the item on the journal line will be registered.';
Visible = false;
}
field("Bin Code"; Rec."Bin Code")
{
ApplicationArea = Warehouse;
ToolTip = 'Specifies a bin code for the item.';
Visible = false;
}
field("Scrap Code"; Rec."Scrap Code")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the scrap code.';
Visible = false;
}
field("Output Quantity"; Rec."Output Quantity")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the quantity of the produced item that can be posted as output on the journal line.';
}
field("Scrap Quantity"; Rec."Scrap Quantity")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the number of units produced incorrectly, and therefore cannot be used.';
}
field("Unit of Measure Code"; Rec."Unit of Measure Code")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies how each unit of the item or resource is measured, such as in pieces or hours. By default, the value in the Base Unit of Measure field on the item or resource card is inserted.';
}
field(Finished; Rec.Finished)
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies that the operation represented by the output journal line is finished.';
}
field("Applies-to Entry"; Rec."Applies-to Entry")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies if the quantity on the journal line must be applied to an already-posted entry. In that case, enter the entry number that the quantity will be applied to.';
}
field("Document Date"; Rec."Document Date")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the date when the related document was created.';
Visible = false;
}
field("External Document No."; Rec."External Document No.")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies a document number that refers to the customer''s or vendor''s numbering system.';
Visible = false;
}
field("Shortcut Dimension 1 Code"; Rec."Shortcut Dimension 1 Code")
{
ApplicationArea = Dimensions;
ToolTip = 'Specifies the code for Shortcut Dimension 1, which is one of two global dimension codes that you set up in the General Ledger Setup window.';
Visible = DimVisible1;
}
field("Shortcut Dimension 2 Code"; Rec."Shortcut Dimension 2 Code")
{
ApplicationArea = Dimensions;
ToolTip = 'Specifies the code for Shortcut Dimension 2, which is one of two global dimension codes that you set up in the General Ledger Setup window.';
Visible = DimVisible2;
}
field(ShortcutDimCode3; ShortcutDimCode[3])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,3';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(3),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible3;
trigger OnValidate()
begin
Rec.ValidateShortcutDimCode(3, ShortcutDimCode[3]);
end;
}
field(ShortcutDimCode4; ShortcutDimCode[4])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,4';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(4),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible4;
trigger OnValidate()
begin
Rec.ValidateShortcutDimCode(4, ShortcutDimCode[4]);
end;
}
field(ShortcutDimCode5; ShortcutDimCode[5])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,5';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(5),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible5;
trigger OnValidate()
begin
Rec.ValidateShortcutDimCode(5, ShortcutDimCode[5]);
end;
}
field(ShortcutDimCode6; ShortcutDimCode[6])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,6';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(6),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible6;
trigger OnValidate()
begin
Rec.ValidateShortcutDimCode(6, ShortcutDimCode[6]);
end;
}
field(ShortcutDimCode7; ShortcutDimCode[7])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,7';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(7),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible7;
trigger OnValidate()
begin
Rec.ValidateShortcutDimCode(7, ShortcutDimCode[7]);
end;
}
field(ShortcutDimCode8; ShortcutDimCode[8])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,8';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(8),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible8;
trigger OnValidate()
begin
Rec.ValidateShortcutDimCode(8, ShortcutDimCode[8]);
end;
}
field("Serial No."; Rec."Serial No.")
{
ApplicationArea = ItemTracking;
ToolTip = 'Specifies the serial number of the item.';
Editable = ItemTrackingEditable;
Visible = CanSelectItemTrackingOnLines;
ExtendedDatatype = Barcode;
trigger OnAssistEdit()
begin
if CanSelectItemTrackingOnLines then
Rec.LookUpTrackingSummary(Enum::"Item Tracking Type"::"Serial No.");
end;
}
field("Lot No."; Rec."Lot No.")
{
ApplicationArea = ItemTracking;
ToolTip = 'Specifies the lot number of the item.';
Editable = ItemTrackingEditable;
Visible = CanSelectItemTrackingOnLines;
ExtendedDatatype = Barcode;
trigger OnAssistEdit()
begin
if CanSelectItemTrackingOnLines then
Rec.LookUpTrackingSummary(Enum::"Item Tracking Type"::"Lot No.");
end;
}
field("Package No."; Rec."Package No.")
{
ApplicationArea = ItemTracking;
ToolTip = 'Specifies the package number of the item.';
Editable = ItemTrackingEditable;
Visible = PackageNoVisible;
ExtendedDatatype = Barcode;
trigger OnAssistEdit()
begin
if CanSelectItemTrackingOnLines then
Rec.LookUpTrackingSummary(Enum::"Item Tracking Type"::"Package No.");
end;
}
field("Expiration Date"; Rec."Expiration Date")
{
ApplicationArea = ItemTracking;
ToolTip = 'Specifies the expiration date, if any, of the item carrying the item tracking number.';
Editable = ExpirationDateEditable;
Visible = CanSelectItemTrackingOnLines;
}
field("Warranty Date"; Rec."Warranty Date")
{
ApplicationArea = ItemTracking;
ToolTip = 'Specifies the warranty expiration date of the item.';
Editable = ItemTrackingEditable;
Visible = CanSelectItemTrackingOnLines;
}
}
group(Control73)
{
ShowCaption = false;
fixed(Control1902114901)
{
ShowCaption = false;
group("Prod. Order Name")
{
Caption = 'Prod. Order Name';
field(ProdOrderDescription; ProdOrderDescription)
{
ApplicationArea = Manufacturing;
Editable = false;
ShowCaption = false;
}
}
group(Operation)
{
Caption = 'Operation';
field(OperationName; OperationName)
{
ApplicationArea = Manufacturing;
Caption = 'Operation';
Editable = false;
ToolTip = 'Specifies the abbreviated task description.';
}
}
}
}
}
area(factboxes)
{
part(JournalErrorsFactBox; "Item Journal Errors FactBox")
{
ApplicationArea = Basic, Suite;
ShowFilter = false;
Visible = BackgroundErrorCheck;
SubPageLink = "Journal Template Name" = field("Journal Template Name"),
"Journal Batch Name" = field("Journal Batch Name"),
"Line No." = field("Line No.");
}
part(WorkflowStatusBatch; "Workflow Status FactBox")
{
ApplicationArea = Suite;
Caption = 'Batch Workflows';
Editable = false;
Enabled = false;
ShowFilter = false;
Visible = ShowWorkflowStatusOnBatch;
}
systempart(Control1900383207; Links)
{
ApplicationArea = RecordLinks;
Visible = false;
}
systempart(Control1905767507; Notes)
{
ApplicationArea = Notes;
Visible = false;
}
}
}
actions
{
area(navigation)
{
group("&Line")
{
Caption = '&Line';
Image = Line;
action(Dimensions)
{
AccessByPermission = TableData Dimension = R;
ApplicationArea = Dimensions;
Caption = 'Dimensions';
Image = Dimensions;
ShortCutKey = 'Alt+D';
ToolTip = 'View or edit dimensions, such as area, project, or department, that you can assign to sales and purchase documents to distribute costs and analyze transaction history.';
trigger OnAction()
begin
Rec.ShowDimensions();
CurrPage.SaveRecord();
end;
}
action("Item Tracking Lines")
{
ApplicationArea = ItemTracking;
Caption = 'Item &Tracking Lines';
Image = ItemTrackingLines;
ShortCutKey = 'Ctrl+Alt+I';
ToolTip = 'View or edit serial, lot and package numbers that are assigned to the item on the document or journal line.';
trigger OnAction()
begin
Rec.OpenItemTrackingLines(false);
end;
}
action("Bin Contents")
{
ApplicationArea = Warehouse;
Caption = 'Bin Contents';
Image = BinContent;
RunObject = Page "Bin Contents List";
RunPageLink = "Location Code" = field("Location Code"),
"Item No." = field("Item No."),
"Variant Code" = field("Variant Code");
RunPageView = sorting("Location Code", "Bin Code", "Item No.", "Variant Code");
ToolTip = 'View items in the bin if the selected line contains a bin code.';
}
}
group("Pro&d. Order")
{
Caption = 'Pro&d. Order';
Image = "Order";
action(Card)
{
ApplicationArea = Manufacturing;
Caption = 'Card';
Image = EditLines;
RunObject = Page "Released Production Order";
RunPageLink = "No." = field("Order No.");
ShortCutKey = 'Shift+F7';
ToolTip = 'View or change detailed information about the record on the document or journal line.';
}
group("Ledger E&ntries")
{
Caption = 'Ledger E&ntries';
Image = Entries;
action("Item Ledger E&ntries")
{
ApplicationArea = Manufacturing;
Caption = 'Item Ledger E&ntries';
Image = ItemLedger;
RunObject = Page "Item Ledger Entries";
RunPageLink = "Order Type" = const(Production),
"Order No." = field("Order No.");
RunPageView = sorting("Order Type", "Order No.");
ShortCutKey = 'Ctrl+F7';
ToolTip = 'View the item ledger entries of the item on the document or journal line.';
}
action("Capacity Ledger Entries")
{
ApplicationArea = Manufacturing;
Caption = 'Capacity Ledger Entries';
Image = CapacityLedger;
RunObject = Page "Capacity Ledger Entries";
RunPageLink = "Order Type" = const(Production),
"Order No." = field("Order No.");
RunPageView = sorting("Order Type", "Order No.");
ToolTip = 'View the capacity ledger entries of the involved production order. Capacity is recorded either as time (run time, stop time, or setup time) or as quantity (scrap quantity or output quantity).';
}
action("Value Entries")
{
ApplicationArea = Manufacturing;
Caption = 'Value Entries';
Image = ValueLedger;
RunObject = Page "Value Entries";
RunPageLink = "Order Type" = const(Production),
"Order No." = field("Order No.");
RunPageView = sorting("Order Type", "Order No.");
ToolTip = 'View the value entries of the item on the document or journal line.';
}
}
action(Approvals)
{
AccessByPermission = TableData "Approval Entry" = R;
ApplicationArea = Suite;
Caption = 'Approvals';
Image = Approvals;
ToolTip = 'View a list of the records that are waiting to be approved. For example, you can see who requested the record to be approved, when it was sent, and when it is due to be approved.';
trigger OnAction()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
ApprovalsMgmt.ShowJournalApprovalEntries(Rec);
end;
}
}
}
area(processing)
{
group("F&unctions")
{
Caption = 'F&unctions';
Image = "Action";
action("Explode &Routing")
{
ApplicationArea = Manufacturing;
Caption = 'Explode &Routing';
Image = ExplodeRouting;
RunObject = Codeunit "Output Jnl.-Expl. Route";
ToolTip = 'Insert prefilled journal lines according to the production order routing.';
}
}
group("Page")
{
Caption = 'Page';
action(EditInExcel)
{
ApplicationArea = Basic, Suite;
Caption = 'Edit in Excel';
Image = Excel;
ToolTip = 'Send the data in the journal to an Excel file for analysis or editing.';
Visible = IsSaaSExcelAddinEnabled;
AccessByPermission = System "Allow Action Export To Excel" = X;
trigger OnAction()
var
ODataUtility: Codeunit ODataUtility;
begin
ODataUtility.EditJournalWorksheetInExcel(Text.CopyStr(CurrPage.Caption, 1, 240), CurrPage.ObjectId(false), Rec."Journal Batch Name", Rec."Journal Template Name");
end;
}
}
group("P&osting")
{
Caption = 'P&osting';
Image = Post;
action("Test Report")
{
ApplicationArea = Manufacturing;
Caption = 'Test Report';
Ellipsis = true;
Image = TestReport;
ToolTip = 'View a test report so that you can find and correct any errors before you perform the actual posting of the journal or document.';
trigger OnAction()
begin
ReportPrint.PrintItemJnlLine(Rec);
end;
}
action(Post)
{
ApplicationArea = Manufacturing;
Caption = 'P&ost';
Image = PostOrder;
ShortCutKey = 'F9';
ToolTip = 'Finalize the document or journal by posting the amounts and quantities to the related accounts in your company books.';
trigger OnAction()
begin
Rec.PostingItemJnlFromProduction(false);
CurrentJnlBatchName := Rec.GetRangeMax("Journal Batch Name");
CurrPage.Update(false);
end;
}
action(PreviewPosting)
{
ApplicationArea = Manufacturing;
Caption = 'Preview Posting';
Image = ViewPostedOrder;
ShortCutKey = 'Ctrl+Alt+F9';
ToolTip = 'Review the different types of entries that will be created when you post the document or journal.';
trigger OnAction()
begin
ShowPreview();
CurrPage.Update(false);
end;
}
action("Post and &Print")
{
ApplicationArea = Manufacturing;
Caption = 'Post and &Print';
Image = PostPrint;
ShortCutKey = 'Shift+F9';
ToolTip = 'Finalize and prepare to print the document or journal. The values and quantities are posted to the related accounts. A report request window where you can specify what to include on the print-out.';
trigger OnAction()
begin
Rec.PostingItemJnlFromProduction(true);
CurrentJnlBatchName := Rec.GetRangeMax("Journal Batch Name");
CurrPage.Update(false);
end;
}
}
action("&Print")
{
ApplicationArea = Manufacturing;
Caption = '&Print';
Ellipsis = true;
Image = Print;
ToolTip = 'Prepare to print the document. A report request window for the document opens where you can specify what to include on the print-out.';
trigger OnAction()
var
ItemJnlLine: Record "Item Journal Line";
begin
ItemJnlLine.Copy(Rec);
ItemJnlLine.PrintInventoryMovement();
end;
}
group("Request Approval")
{
Caption = 'Request Approval';
group(SendApprovalRequest)
{
Caption = 'Send Approval Request';
Image = SendApprovalRequest;
action(SendApprovalRequestJournalBatch)
{
ApplicationArea = Basic, Suite;
Caption = 'Journal Batch';
Enabled = not OpenApprovalEntriesOnJnlBatchExist and CanRequestFlowApprovalForBatch and EnabledItemJnlBatchWorkflowsExist;
Image = SendApprovalRequest;
ToolTip = 'Send all journal lines for approval, also those that you may not see because of filters.';
trigger OnAction()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
ApprovalsMgmt.TrySendJournalBatchApprovalRequest(Rec);
SetControlAppearanceFromBatch();
end;
}
}
group(CancelApprovalRequest)
{
Caption = 'Cancel Approval Request';
Image = Cancel;
action(CancelApprovalRequestJournalBatch)
{
ApplicationArea = Basic, Suite;
Caption = 'Journal Batch';
Enabled = CanCancelApprovalForJnlBatch or CanCancelFlowApprovalForBatch;
Image = CancelApprovalRequest;
ToolTip = 'Cancel sending all journal lines for approval, also those that you may not see because of filters.';
trigger OnAction()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
ApprovalsMgmt.TryCancelJournalBatchApprovalRequest(Rec);
SetControlAppearanceFromBatch();
end;
}
}
group(Flow)
{
Caption = 'Power Automate';
Image = Flow;
customaction(CreateApprovalFlowFromTemplate)
{
ApplicationArea = Basic, Suite;
Caption = 'Create approval flow';
ToolTip = 'Create a new flow in Power Automate from a list of relevant flow templates.';
Visible = IsSaaS and IsPowerAutomatePrivacyNoticeApproved;
CustomActionType = FlowTemplateGallery;
FlowTemplateCategoryName = 'd365bc_approval_itemJournal';
}
}
}
group(Approval)
{
Caption = 'Approval';
action(Approve)
{
ApplicationArea = All;
Caption = 'Approve';
Image = Approve;
ToolTip = 'Approve the requested changes.';
Visible = OpenApprovalEntriesExistForCurrUser;
trigger OnAction()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
ApprovalsMgmt.ApproveItemJournalRequest(Rec);
end;
}
action(Reject)
{
ApplicationArea = All;
Caption = 'Reject';
Image = Reject;
ToolTip = 'Reject the approval request.';
Visible = OpenApprovalEntriesExistForCurrUser;
trigger OnAction()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
ApprovalsMgmt.RejectItemJournalRequest(Rec);
end;
}
action(Delegate)
{
ApplicationArea = All;
Caption = 'Delegate';
Image = Delegate;
ToolTip = 'Delegate the approval to a substitute approver.';
Visible = OpenApprovalEntriesExistForCurrUser;
trigger OnAction()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
ApprovalsMgmt.DelegateItemJournalRequest(Rec);
end;
}
action(Comments)
{
ApplicationArea = All;
Caption = 'Comments';
Image = ViewComments;
ToolTip = 'View or add comments for the record.';
Visible = OpenApprovalEntriesExistForCurrUser or ApprovalEntriesExistSentByCurrentUser;
trigger OnAction()
var
ItemJournalBatch: Record "Item Journal Batch";
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
if OpenApprovalEntriesOnJnlBatchExist then
if ItemJournalBatch.Get(Rec."Journal Template Name", Rec."Journal Batch Name") then
ApprovalsMgmt.GetApprovalComment(ItemJournalBatch);
end;
}
}
group(Errors)
{
Caption = 'Issues';
Image = ErrorLog;
Visible = BackgroundErrorCheck;
action(ShowLinesWithErrors)
{
ApplicationArea = Basic, Suite;
Caption = 'Show Lines with Issues';
Image = Error;
Visible = BackgroundErrorCheck;
Enabled = not ShowAllLinesEnabled;
ToolTip = 'View a list of journal lines that have issues before you post the journal.';
trigger OnAction()
begin
Rec.SwitchLinesWithErrorsFilter(ShowAllLinesEnabled);
end;
}
action(ShowAllLines)
{
ApplicationArea = Basic, Suite;
Caption = 'Show All Lines';
Image = ExpandAll;
Visible = BackgroundErrorCheck;
Enabled = ShowAllLinesEnabled;
ToolTip = 'View all journal lines, including lines with and without issues.';
trigger OnAction()
begin
Rec.SwitchLinesWithErrorsFilter(ShowAllLinesEnabled);
end;
}
}
}
area(Promoted)
{
group(Category_Process)
{
Caption = 'Process', Comment = 'Generated from the PromotedActionCategories property index 1.';
group(Category_Category4)
{
Caption = 'Posting';
ShowAs = SplitButton;
actionref(Post_Promoted; Post)
{
}
actionref(PreviewPosting_Promoted; PreviewPosting)
{
}
actionref("Post and &Print_Promoted"; "Post and &Print")
{
}
}
actionref("&Print_Promoted"; "&Print")
{
}
actionref("Explode &Routing_Promoted"; "Explode &Routing")
{
}
}
group(Category_Category8)
{
Caption = 'Approve', Comment = 'Generated from the PromotedActionCategories property index 7.';
actionref(Approve_Promoted; Approve)
{
}
actionref(Reject_Promoted; Reject)
{
}
actionref(Comments_Promoted; Comments)
{
}
actionref(Delegate_Promoted; Delegate)
{
}
}
group("Category_Request Approval")
{
Caption = 'Request Approval';
group("Category_Send Approval Request")
{
Caption = 'Send Approval Request';
actionref(SendApprovalRequestJournalBatch_Promoted; SendApprovalRequestJournalBatch)
{
}
}
group("Category_Cancel Approval Request")
{
Caption = 'Cancel Approval Request';
actionref(CancelApprovalRequestJournalBatch_Promoted; CancelApprovalRequestJournalBatch)
{
}
}
}
group(Category_Category5)
{
Caption = 'Line', Comment = 'Generated from the PromotedActionCategories property index 4.';
actionref("Item Tracking Lines_Promoted"; "Item Tracking Lines")
{
}
actionref(Dimensions_Promoted; Dimensions)
{
}
actionref(Approvals_Promoted; Approvals)
{
}
}
group(Category_Category6)
{
Caption = 'Prod. Order', Comment = 'Generated from the PromotedActionCategories property index 5.';
actionref("Item Ledger E&ntries_Promoted"; "Item Ledger E&ntries")
{
}
actionref("Capacity Ledger Entries_Promoted"; "Capacity Ledger Entries")
{
}
actionref("Value Entries_Promoted"; "Value Entries")
{
}
}
group(Category_Category7)
{
Caption = 'Page', Comment = 'Generated from the PromotedActionCategories property index 6.';
actionref(ShowLinesWithErrors_Promoted; ShowLinesWithErrors)
{
}
actionref(ShowAllLines_Promoted; ShowAllLines)
{
}
}
group(Category_Report)
{
Caption = 'Report', Comment = 'Generated from the PromotedActionCategories property index 2.';
}
}
}
trigger OnAfterGetCurrRecord()
var
ItemJournalBatch: Record "Item Journal Batch";
begin
MfgItemJournalMgt.GetOutput(Rec, ProdOrderDescription, OperationName);
ItemTrackingEditable := false;
if CanSelectItemTrackingOnLines then
ItemTrackingEditable := not Rec.ReservEntryExist();
ExpirationDateEditable := SetExpirationDateVisibility();
if ItemJournalBatch.Get(Rec.GetRangeMax("Journal Template Name"), CurrentJnlBatchName) then begin
ItemJournalBatch.SetApprovalStateForBatch(ItemJournalBatch, Rec, OpenApprovalEntriesExistForCurrUser, OpenApprovalEntriesOnJnlBatchExist, CanCancelApprovalForJnlBatch, CanRequestFlowApprovalForBatch, CanCancelFlowApprovalForBatch, ApprovalEntriesExistSentByCurrentUser, EnabledItemJnlBatchWorkflowsExist);
ShowWorkflowStatusOnBatch := CurrPage.WorkflowStatusBatch.Page.SetFilterOnWorkflowRecord(ItemJournalBatch.RecordId());
end;
ApprovalMgmt.GetItemJnlBatchApprovalStatus(Rec, ItemJnlBatchApprovalStatus, EnabledItemJnlBatchWorkflowsExist);
end;
trigger OnAfterGetRecord()
begin
Rec.ShowShortcutDimCode(ShortcutDimCode);
ItemTrackingEditable := false;
if CanSelectItemTrackingOnLines then
ItemTrackingEditable := not Rec.ReservEntryExist();
ExpirationDateEditable := SetExpirationDateVisibility();
if ClientTypeManagement.GetCurrentClientType() = CLIENTTYPE::ODataV4 then
SetItemTrackingFieldsEditabilityForOData();
end;
trigger OnInit()
begin
IsPowerAutomatePrivacyNoticeApproved := PrivacyNotice.GetPrivacyNoticeApprovalState(FlowServiceManagement.GetPowerAutomatePrivacyNoticeId()) = "Privacy Notice Approval State"::Agreed;
end;
trigger OnDeleteRecord(): Boolean
var
ItemJnlLineReserve: Codeunit "Item Jnl. Line-Reserve";
begin
Commit();
if not ItemJnlLineReserve.DeleteLineConfirm(Rec) then
exit(false);
ItemJnlLineReserve.DeleteLine(Rec);
end;
trigger OnModifyRecord(): Boolean
begin
ApprovalMgmt.CleanItemJournalApprovalStatus(Rec, ItemJnlBatchApprovalStatus);
end;
trigger OnNewRecord(BelowxRec: Boolean)
begin
Rec.SetUpNewLine(xRec);
Rec.Validate("Entry Type", Rec."Entry Type"::Output);
Clear(ShortcutDimCode);
end;
trigger OnOpenPage()
var
ServerSetting: Codeunit "Server Setting";
EnvironmentInfo: Codeunit "Environment Information";
JnlSelected: Boolean;
begin
IsSaaSExcelAddinEnabled := ServerSetting.GetIsSaasExcelAddinEnabled();
IsSaaS := EnvironmentInfo.IsSaaS();
if ClientTypeManagement.GetCurrentClientType() = CLIENTTYPE::ODataV4 then
exit;
SetDimensionsVisibility();
if Rec.IsOpenedFromBatch() then begin
CurrentJnlBatchName := Rec."Journal Batch Name";
ItemJnlMgt.OpenJnl(CurrentJnlBatchName, Rec);
SetControlAppearanceFromBatch();
exit;
end;
ItemJnlMgt.TemplateSelection(PAGE::"Output Journal", 5, false, Rec, JnlSelected);
if not JnlSelected then
Error('');
ItemJnlMgt.OpenJnl(CurrentJnlBatchName, Rec);
SetControlAppearanceFromBatch();
end;
var
ItemJnlMgt: Codeunit ItemJnlManagement;
MfgItemJournalMgt: Codeunit "Mfg. Item Journal Mgt.";
ReportPrint: Codeunit "Test Report-Print";
ClientTypeManagement: Codeunit "Client Type Management";
ItemJournalErrorsMgt: Codeunit "Item Journal Errors Mgt.";
ApprovalMgmt: Codeunit "Approvals Mgmt.";
PrivacyNotice: Codeunit "Privacy Notice";
FlowServiceManagement: Codeunit "Flow Service Management";
ProdOrderDescription: Text[100];
OperationName: Text[100];
ItemJnlBatchApprovalStatus: Text[20];
BackgroundErrorCheck: Boolean;
ShowAllLinesEnabled: Boolean;
IsSaaSExcelAddinEnabled: Boolean;
ApprovalEntriesExistSentByCurrentUser: Boolean;
OpenApprovalEntriesExistForCurrUser: Boolean;
OpenApprovalEntriesOnJnlBatchExist: Boolean;
EnabledItemJnlBatchWorkflowsExist: Boolean;
ShowWorkflowStatusOnBatch: Boolean;
CanCancelApprovalForJnlBatch: Boolean;
CanRequestFlowApprovalForBatch: Boolean;
CanCancelFlowApprovalForBatch: Boolean;
IsPowerAutomatePrivacyNoticeApproved: Boolean;
IsSaaS: Boolean;
protected var
CurrentJnlBatchName: Code[10];
ShortcutDimCode: array[8] of Code[20];
DimVisible1: Boolean;
DimVisible2: Boolean;
DimVisible3: Boolean;
DimVisible4: Boolean;
DimVisible5: Boolean;
DimVisible6: Boolean;
DimVisible7: Boolean;
DimVisible8: Boolean;
CanSelectItemTrackingOnLines, ItemTrackingEditable, PackageNoVisible, ExpirationDateEditable : Boolean;
local procedure CurrentJnlBatchNameOnAfterValidate()
begin
CurrPage.SaveRecord();
ItemJnlMgt.SetName(CurrentJnlBatchName, Rec);
SetControlAppearanceFromBatch();
CurrPage.Update(false);
end;
local procedure SetControlAppearanceFromBatch()
var
ItemJournalBatch: Record "Item Journal Batch";
ItemTrackingCode: Record "Item Tracking Code";
BackgroundErrorHandlingMgt: Codeunit "Background Error Handling Mgt.";
begin
if not ItemJournalBatch.Get(Rec.GetRangeMax("Journal Template Name"), CurrentJnlBatchName) then
exit;
BackgroundErrorCheck := BackgroundErrorHandlingMgt.BackgroundValidationFeatureEnabled();
ShowAllLinesEnabled := true;
CanSelectItemTrackingOnLines := ItemJournalBatch."Item Tracking on Lines";
ItemTrackingCode.SetRange("Package Specific Tracking", true);
PackageNoVisible := CanSelectItemTrackingOnLines and not ItemTrackingCode.IsEmpty();
ShowWorkflowStatusOnBatch := CurrPage.WorkflowStatusBatch.Page.SetFilterOnWorkflowRecord(ItemJournalBatch.RecordId());
ItemJournalBatch.SetApprovalStateForBatch(ItemJournalBatch, Rec, OpenApprovalEntriesExistForCurrUser, OpenApprovalEntriesOnJnlBatchExist, CanCancelApprovalForJnlBatch, CanRequestFlowApprovalForBatch, CanCancelFlowApprovalForBatch, ApprovalEntriesExistSentByCurrentUser, EnabledItemJnlBatchWorkflowsExist);
Rec.SwitchLinesWithErrorsFilter(ShowAllLinesEnabled);
ItemJournalErrorsMgt.SetFullBatchCheck(true);
end;
procedure ItemNoOnAfterValidate()
begin
Rec.ShowShortcutDimCode(ShortcutDimCode);
end;
local procedure SetDimensionsVisibility()
var
DimMgt: Codeunit DimensionManagement;
begin
DimVisible1 := false;
DimVisible2 := false;
DimVisible3 := false;
DimVisible4 := false;
DimVisible5 := false;
DimVisible6 := false;
DimVisible7 := false;
DimVisible8 := false;
DimMgt.UseShortcutDims(
DimVisible1, DimVisible2, DimVisible3, DimVisible4, DimVisible5, DimVisible6, DimVisible7, DimVisible8);
Clear(DimMgt);
end;
local procedure SetExpirationDateVisibility(): Boolean
var
Item: Record Item;
ItemTrackingCode: Record "Item Tracking Code";
begin
if not ItemTrackingEditable then
exit(false);
if Rec."Item No." = '' then
exit(false);
Item.SetLoadFields("Item Tracking Code");
Item.Get(Rec."Item No.");
if Item."Item Tracking Code" = '' then
exit(false);
ItemTrackingCode.SetLoadFields("Use Expiration Dates");
ItemTrackingCode.Get(Item."Item Tracking Code");
exit(ItemTrackingCode."Use Expiration Dates");
end;
local procedure ShowPreview()
begin
Rec.PreviewPostItemJnlFromProduction();
end;
local procedure SetItemTrackingFieldsEditabilityForOData()
var
ItemJournalBatch: Record "Item Journal Batch";
begin
if ItemJournalBatch.Get(Rec."Journal Template Name", Rec."Journal Batch Name") then begin
CanSelectItemTrackingOnLines := ItemJournalBatch."Item Tracking on Lines";
ItemTrackingEditable := CanSelectItemTrackingOnLines;
CurrPage.Update(false);
end;
end;
[IntegrationEvent(false, false)]
local procedure OnReferenceNoOnAfterLookup(var ItemJournalLine: Record "Item Journal Line")
begin
end;
}