Codeunit 5008 Return Receipt PDF Doc.Handler

// ------------------------------------------------------------------------------------------------
// Copyright (c) Microsoft Corporation. All rights reserved.
// Licensed under the MIT License. See License.txt in the project root for license information.
// ------------------------------------------------------------------------------------------------
namespace Microsoft.EServices.EDocument;

using Microsoft.Foundation.Reporting;
using Microsoft.Integration.Graph;
using Microsoft.Sales.History;
using System.EMail;
using System.Utilities;

codeunit 5008 "Return Receipt PDF Doc.Handler" implements IPdfDocumentHandler
{
    var
        ReturnReceiptLbl: Label 'Return Receipt';

    /// <summary>
    /// Generates a PDF blob for Return Receipt
    /// </summary>
    /// <param name="DocumentId">Document ID</param>
    /// <param name="DocumentType">Document Type</param>
    /// <param name="TempAttachmentEntityBuffer">The buffer to store successfully generated report</param>
    /// <returns>True if the generated report successfully added to the buffer, otherwise false.</returns>    
    procedure GeneratePdfBlobWithDocumentType(DocumentId: Guid; DocumentType: Enum "Attachment Entity Buffer Document Type"; var TempAttachmentEntityBuffer: Record "Attachment Entity Buffer" temporary): Boolean
    var
        ReturnReceiptHeader: Record "Return Receipt Header";
        ReportSelections: Record "Report Selections";
        DocumentMailing: Codeunit "Document-Mailing";
        PDFDocumentManagement: Codeunit "PDF Document Management";
        TempBlob: Codeunit "Temp Blob";
        Name: Text[250];
        ReportUsage: Enum "Report Selection Usage";
    begin
        if not ReturnReceiptHeader.GetBySystemId(DocumentId) then
            exit(false);

        ReturnReceiptHeader.SetRange("No.", ReturnReceiptHeader."No.");
        ReportUsage := "Report Selection Usage"::"S.Ret.Rcpt.";
        ReportSelections.GetPdfReportForCust(TempBlob, ReportUsage, ReturnReceiptHeader, ReturnReceiptHeader."Bill-to Customer No.");
        DocumentMailing.GetAttachmentFileName(Name, ReturnReceiptHeader."No.", ReturnReceiptLbl, ReportUsage.AsInteger());
        exit(PDFDocumentManagement.AddToTempAttachmentEntityBuffer(DocumentId, DocumentType, TempBlob, Name, TempAttachmentEntityBuffer));
    end;
}