Page 5797 Registered Whse. Activity List

// ------------------------------------------------------------------------------------------------
// Copyright (c) Microsoft Corporation. All rights reserved.
// Licensed under the MIT License. See License.txt in the project root for license information.
// ------------------------------------------------------------------------------------------------
namespace Microsoft.Warehouse.Activity.History;

using Microsoft.Warehouse.Journal;

page 5797 "Registered Whse. Activity List"
{
    Caption = 'Registered Whse. Activity List';
    Editable = false;
    PageType = List;
    SourceTable = "Registered Whse. Activity Hdr.";

    layout
    {
        area(content)
        {
            repeater(Control1)
            {
                ShowCaption = false;
                field(Type; Rec.Type)
                {
                    ApplicationArea = Warehouse;
                    Visible = false;
                }
                field("No."; Rec."No.")
                {
                    ApplicationArea = Warehouse;
                }
                field("Whse. Activity No."; Rec."Whse. Activity No.")
                {
                    ApplicationArea = Warehouse;
                }
                field("Location Code"; Rec."Location Code")
                {
                    ApplicationArea = Location;
                }
                field("Assigned User ID"; Rec."Assigned User ID")
                {
                    ApplicationArea = Warehouse;
                }
                field("Sorting Method"; Rec."Sorting Method")
                {
                    ApplicationArea = Warehouse;
                }
                field("No. Series"; Rec."No. Series")
                {
                    ApplicationArea = Warehouse;
                }
            }
        }
        area(factboxes)
        {
            systempart(Control1900383207; Links)
            {
                ApplicationArea = RecordLinks;
                Visible = false;
            }
            systempart(Control1905767507; Notes)
            {
                ApplicationArea = Notes;
                Visible = false;
            }
        }
    }

    actions
    {
        area(navigation)
        {
            group("&Line")
            {
                Caption = '&Line';
                Image = Line;
                action(Card)
                {
                    ApplicationArea = Warehouse;
                    Caption = 'Card';
                    Image = EditLines;
                    ShortCutKey = 'Shift+F7';
                    ToolTip = 'View or change detailed information about the record on the document or journal line.';

                    trigger OnAction()
                    begin
                        case Rec.Type of
                            Rec.Type::"Put-away":
                                PAGE.Run(PAGE::"Registered Put-away", Rec);
                            Rec.Type::Pick:
                                PAGE.Run(PAGE::"Registered Pick", Rec);
                            Rec.Type::Movement:
                                PAGE.Run(PAGE::"Registered Movement", Rec);
                        end;
                    end;
                }
            }
        }
    }

    trigger OnAfterGetCurrRecord()
    begin
        CurrPage.Caption := FormCaption();
    end;

    trigger OnOpenPage()
    var
        WMSManagement: Codeunit "WMS Management";
    begin
        Rec.FilterGroup(2);
        Rec.SetFilter("Location Code", WMSManagement.GetWarehouseEmployeeLocationFilter(CopyStr(UserId, 1, 50)));
        Rec.FilterGroup(0);
    end;

    var
#pragma warning disable AA0074
        Text000: Label 'Registered Whse. Put-away List';
        Text001: Label 'Registered Whse. Pick List';
        Text002: Label 'Registered Whse. Movement List';
        Text003: Label 'Registered Whse. Activity List';
#pragma warning restore AA0074

    local procedure FormCaption(): Text[250]
    begin
        case Rec.Type of
            Rec.Type::"Put-away":
                exit(Text000);
            Rec.Type::Pick:
                exit(Text001);
            Rec.Type::Movement:
                exit(Text002);
            else
                exit(Text003);
        end;
    end;
}