Page 9311 Purchase Return Order List
- App
- Base Application
- Namespace
- Microsoft.Purchases.Document
- Versions
- 17-28
- Source table
- 38
Versions171819202122232425262728
Source29
Source in 29
src/Layers/W1/BaseApp/Purchases/Document/PurchaseReturnOrderList.Page.al920 lines, Copyright (c) Microsoft Corporation. MIT
// ------------------------------------------------------------------------------------------------
// Copyright (c) Microsoft Corporation. All rights reserved.
// Licensed under the MIT License. See License.txt in the project root for license information.
// ------------------------------------------------------------------------------------------------
namespace Microsoft.Purchases.Document;
using Microsoft.Finance.Dimension;
using Microsoft.Foundation.Attachment;
using Microsoft.Foundation.BatchProcessing;
using Microsoft.Foundation.Reporting;
using Microsoft.Intercompany;
using Microsoft.Intercompany.GLAccount;
using Microsoft.Purchases.Comment;
using Microsoft.Purchases.History;
using Microsoft.Purchases.Posting;
using Microsoft.Purchases.Setup;
using Microsoft.Purchases.Vendor;
using Microsoft.Warehouse.Activity;
using Microsoft.Warehouse.Document;
using Microsoft.Warehouse.InventoryDocument;
using Microsoft.Warehouse.Request;
using System.Automation;
using System.Text;
using System.Threading;
page 9311 "Purchase Return Order List"
{
ApplicationArea = PurchReturnOrder;
Caption = 'Purchase Return Orders';
CardPageID = "Purchase Return Order";
DataCaptionFields = "Buy-from Vendor No.";
Editable = false;
PageType = List;
AboutTitle = 'About Purchase Return Orders';
AboutText = 'Create and manage purchase return orders to process returns to vendors, reverse posted costs, specify return reasons, and generate replacement orders when needed.';
QueryCategory = 'Purchase Return Orders';
RefreshOnActivate = true;
SourceTable = "Purchase Header";
SourceTableView = where("Document Type" = const("Return Order"));
UsageCategory = Lists;
layout
{
area(content)
{
repeater(Control1)
{
ShowCaption = false;
field("No."; Rec."No.")
{
ApplicationArea = PurchReturnOrder;
ToolTip = 'Specifies the number of the involved entry or record, according to the specified number series.';
}
field("Buy-from Vendor No."; Rec."Buy-from Vendor No.")
{
ApplicationArea = PurchReturnOrder;
ToolTip = 'Specifies the name of the vendor who delivered the items.';
}
field("Order Address Code"; Rec."Order Address Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Buy-from Vendor Name"; Rec."Buy-from Vendor Name")
{
ApplicationArea = PurchReturnOrder;
ToolTip = 'Specifies the name of the vendor who delivered the items.';
}
field("Vendor Authorization No."; Rec."Vendor Authorization No.")
{
ApplicationArea = PurchReturnOrder;
}
field("Buy-from Post Code"; Rec."Buy-from Post Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Buy-from Country/Region Code"; Rec."Buy-from Country/Region Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Buy-from Contact"; Rec."Buy-from Contact")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Pay-to Vendor No."; Rec."Pay-to Vendor No.")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Pay-to Name"; Rec."Pay-to Name")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Pay-to Post Code"; Rec."Pay-to Post Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Pay-to Country/Region Code"; Rec."Pay-to Country/Region Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Pay-to Contact"; Rec."Pay-to Contact")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Ship-to Code"; Rec."Ship-to Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Ship-to Name"; Rec."Ship-to Name")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Ship-to Post Code"; Rec."Ship-to Post Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Ship-to Country/Region Code"; Rec."Ship-to Country/Region Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Ship-to Contact"; Rec."Ship-to Contact")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Posting Date"; Rec."Posting Date")
{
ApplicationArea = PurchReturnOrder;
ToolTip = 'Specifies the entry''s posting date.';
Visible = false;
}
field("Shortcut Dimension 1 Code"; Rec."Shortcut Dimension 1 Code")
{
ApplicationArea = Dimensions;
Visible = false;
}
field("Shortcut Dimension 2 Code"; Rec."Shortcut Dimension 2 Code")
{
ApplicationArea = Dimensions;
Visible = false;
}
field("Location Code"; Rec."Location Code")
{
ApplicationArea = PurchReturnOrder;
ToolTip = 'Specifies the location where the items are to be shipped. This field acts as the default location for new lines. You can update the location code for individual lines as needed.';
}
field("Purchaser Code"; Rec."Purchaser Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Assigned User ID"; Rec."Assigned User ID")
{
ApplicationArea = PurchReturnOrder;
}
field("Currency Code"; Rec."Currency Code")
{
ApplicationArea = PurchReturnOrder;
ToolTip = 'Specifies the currency that is used on the entry.';
Visible = false;
}
field("Document Date"; Rec."Document Date")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field(Status; Rec.Status)
{
ApplicationArea = PurchReturnOrder;
ToolTip = 'Specifies if the record is open, waiting to be approved, invoiced for prepayment, or released to the next stage of processing.';
StyleExpr = StatusStyleTxt;
}
field("Payment Terms Code"; Rec."Payment Terms Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Due Date"; Rec."Due Date")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Payment Discount %"; Rec."Payment Discount %")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Shipment Method Code"; Rec."Shipment Method Code")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Completely Received"; Rec."Completely Received")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Campaign No."; Rec."Campaign No.")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Applies-to Doc. Type"; Rec."Applies-to Doc. Type")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Expected Receipt Date"; Rec."Expected Receipt Date")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Job Queue Status"; Rec."Job Queue Status")
{
ApplicationArea = PurchReturnOrder;
Style = Unfavorable;
StyleExpr = Rec."Job Queue Status" = Rec."Job Queue Status"::ERROR;
ToolTip = 'Specifies the status of a job queue entry that handles the posting of purchase return orders.';
Visible = JobQueueActive;
trigger OnDrillDown()
var
JobQueueEntry: Record "Job Queue Entry";
begin
if Rec."Job Queue Status" = Rec."Job Queue Status"::" " then
exit;
JobQueueEntry.ShowStatusMsg(Rec."Job Queue Entry ID");
end;
}
field(Amount; Rec.Amount)
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Amount Including VAT"; Rec."Amount Including VAT")
{
ApplicationArea = PurchReturnOrder;
Visible = false;
}
field("Posting Description"; Rec."Posting Description")
{
ApplicationArea = Suite;
Visible = false;
}
}
}
area(factboxes)
{
part(Control1901138007; "Vendor Details FactBox")
{
ApplicationArea = PurchReturnOrder;
SubPageLink = "No." = field("Buy-from Vendor No."),
"Date Filter" = field("Date Filter");
}
part("Attached Documents List"; "Doc. Attachment List Factbox")
{
ApplicationArea = All;
Caption = 'Documents';
UpdatePropagation = Both;
SubPageLink = "Table ID" = const(Database::"Purchase Header"), "No." = field("No."), "Document Type" = field("Document Type");
}
systempart(Control1900383207; Links)
{
ApplicationArea = RecordLinks;
Visible = false;
}
systempart(Control1905767507; Notes)
{
ApplicationArea = Notes;
Visible = false;
}
}
}
actions
{
area(navigation)
{
group("&Return Order")
{
Caption = '&Return Order';
Image = Return;
action(PurchaseOrderStatistics)
{
ApplicationArea = Basic, Suite;
Caption = 'Statistics';
Enabled = Rec."No." <> '';
Image = Statistics;
ShortCutKey = 'F7';
Visible = true;
ToolTip = 'View statistical information, such as the value of posted entries, for the record.';
RunObject = Page "Purchase Order Statistics";
RunPageOnRec = true;
}
action(VendorStatistics)
{
ApplicationArea = Basic, Suite;
Caption = 'Vendor Statistics';
Enabled = Rec."Buy-from Vendor No." <> '';
Image = Statistics;
RunObject = Page "Vendor Statistics";
RunPageLink = "No." = field("Buy-from Vendor No."),
"Date Filter" = field("Date Filter");
ToolTip = 'View statistical information, such as the value of posted entries, for the sell-to customer on the sales document.';
}
action(Dimensions)
{
AccessByPermission = TableData Dimension = R;
ApplicationArea = Dimensions;
Caption = 'Dimensions';
Image = Dimensions;
ShortCutKey = 'Alt+D';
ToolTip = 'View or edit dimensions, such as area, project, or department, that you can assign to sales and purchase documents to distribute costs and analyze transaction history.';
trigger OnAction()
begin
Rec.ShowDocDim();
end;
}
action(Approvals)
{
AccessByPermission = TableData "Approval Entry" = R;
ApplicationArea = PurchReturnOrder;
Caption = 'Approvals';
Image = Approvals;
//The property 'PromotedCategory' can only be set if the property 'Promoted' is set to 'true'
//PromotedCategory = Category4;
//The property 'PromotedOnly' can only be set if the property 'Promoted' is set to 'true'
//PromotedOnly = true;
ToolTip = 'View a list of the records that are waiting to be approved. For example, you can see who requested the record to be approved, when it was sent, and when it is due to be approved.';
trigger OnAction()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
ApprovalsMgmt.OpenApprovalsPurchase(Rec);
end;
}
action("Co&mments")
{
ApplicationArea = Comments;
Caption = 'Co&mments';
Image = ViewComments;
RunObject = Page "Purch. Comment Sheet";
RunPageLink = "Document Type" = field("Document Type"),
"No." = field("No."),
"Document Line No." = const(0);
ToolTip = 'View or add comments for the record.';
}
}
group(Documents)
{
Caption = 'Documents';
Image = Documents;
action("Return Shipments")
{
ApplicationArea = PurchReturnOrder;
Caption = 'Return Shipments';
Image = Shipment;
RunObject = Page "Posted Return Shipments";
RunPageLink = "Return Order No." = field("No.");
RunPageView = sorting("Return Order No.");
ToolTip = 'Open the posted return shipments related to this order.';
}
action("Cred&it Memos")
{
ApplicationArea = PurchReturnOrder;
Caption = 'Cred&it Memos';
Image = CreditMemo;
ToolTip = 'View a list of ongoing credit memos for the order.';
trigger OnAction()
var
TempPurchCrMemoHdr: Record "Purch. Cr. Memo Hdr." temporary;
PurchGetReturnShipment: Codeunit "Purch.-Get Return Shipments";
begin
PurchGetReturnShipment.GetPurchRetOrderCrMemos(TempPurchCrMemoHdr, Rec."No.");
Page.Run(Page::"Posted Purchase Credit Memos", TempPurchCrMemoHdr);
end;
}
separator(Action1102601034)
{
}
}
group(Warehouse)
{
Caption = 'Warehouse';
Image = Warehouse;
action("In&vt. Put-away/Pick Lines")
{
ApplicationArea = Warehouse;
Caption = 'In&vt. Put-away/Pick Lines';
Image = PickLines;
RunObject = Page "Warehouse Activity List";
RunPageLink = "Source Document" = const("Purchase Return Order"),
"Source No." = field("No.");
RunPageView = sorting("Source Document", "Source No.", "Location Code");
ToolTip = 'View items that are inbound or outbound on inventory put-away or inventory pick documents for the purchase return order.';
}
action("Warehouse Shipment Lines")
{
ApplicationArea = Warehouse;
Caption = 'Warehouse Shipment Lines';
Image = ShipmentLines;
RunObject = Page "Whse. Shipment Lines";
RunPageLink = "Source Type" = const(39),
#pragma warning disable AL0603
"Source Subtype" = field("Document Type"),
#pragma warning restore
"Source No." = field("No.");
RunPageView = sorting("Source Type", "Source Subtype", "Source No.", "Source Line No.");
ToolTip = 'View ongoing warehouse shipments for the document, in advanced warehouse configurations.';
}
action("Whse. Pick Lines")
{
ApplicationArea = Warehouse;
Caption = 'Warehouse Pick Lines';
Image = PickLines;
RunObject = page "Warehouse Activity Lines";
RunPageLink = "Source Document" = const("Purchase Return Order"), "Source No." = field("No.");
RunPageView = sorting("Source Type", "Source Subtype", "Source No.");
ToolTip = 'View ongoing warehouse picks for the document, in advanced warehouse configurations.';
}
}
}
area(processing)
{
action(Print)
{
ApplicationArea = PurchReturnOrder;
Caption = '&Print';
Ellipsis = true;
Image = Print;
ToolTip = 'Prepare to print the document. A report request window for the document opens where you can specify what to include on the print-out.';
trigger OnAction()
begin
DocPrint.PrintPurchHeader(Rec);
end;
}
action(Email)
{
ApplicationArea = Basic, Suite;
Caption = 'Send by Email';
Ellipsis = true;
Image = Email;
ToolTip = 'Finalize and prepare to email the document. The Send Email window opens prefilled with the vendor''s email address so you can add or edit information.';
trigger OnAction()
var
DocPrint: Codeunit "Document-Print";
begin
DocPrint.EmailPurchHeader(Rec);
end;
}
action(Send)
{
ApplicationArea = Basic, Suite;
Caption = 'Send';
Ellipsis = true;
Image = SendToMultiple;
ToolTip = 'Prepare to send the document according to the vendor''s sending profile, such as attached to an email. The Send document to window opens first so you can confirm or select a sending profile.';
trigger OnAction()
var
PurchaseHeader: Record "Purchase Header";
begin
PurchaseHeader := Rec;
CurrPage.SetSelectionFilter(PurchaseHeader);
PurchaseHeader.SendRecords();
end;
}
action(AttachAsPDF)
{
ApplicationArea = Basic, Suite;
Caption = 'Attach as PDF';
Image = PrintAttachment;
ToolTip = 'Create a PDF file and attach it to the document.';
trigger OnAction()
var
PurchaseHeader: Record "Purchase Header";
DocPrint: Codeunit "Document-Print";
begin
PurchaseHeader := Rec;
CurrPage.SetSelectionFilter(PurchaseHeader);
DocPrint.PrintPurchaseHeaderToDocumentAttachment(PurchaseHeader);
end;
}
group(Action7)
{
Caption = 'Release';
Image = ReleaseDoc;
action(Release)
{
ApplicationArea = PurchReturnOrder;
Caption = 'Re&lease';
Image = ReleaseDoc;
ShortCutKey = 'Ctrl+F9';
ToolTip = 'Release the document to the next stage of processing. You must reopen the document before you can make changes to it.';
trigger OnAction()
var
PurchaseHeader: Record "Purchase Header";
begin
CurrPage.SetSelectionFilter(PurchaseHeader);
Rec.PerformManualRelease(PurchaseHeader);
end;
}
action(Reopen)
{
ApplicationArea = PurchReturnOrder;
Caption = 'Re&open';
Image = ReOpen;
ToolTip = 'Reopen the document to change it after it has been approved. Approved documents have the Released status and must be opened before they can be changed';
trigger OnAction()
var
PurchaseHeader: Record "Purchase Header";
begin
CurrPage.SetSelectionFilter(PurchaseHeader);
Rec.PerformManualReopen(PurchaseHeader);
end;
}
separator(Action1102601023)
{
}
}
group("F&unctions")
{
Caption = 'F&unctions';
Image = "Action";
action("Get Posted Doc&ument Lines to Reverse")
{
ApplicationArea = PurchReturnOrder;
Caption = 'Get Posted Doc&ument Lines to Reverse';
Ellipsis = true;
Image = ReverseLines;
ToolTip = 'Copy one or more posted purchase document lines in order to reverse the original order.';
trigger OnAction()
begin
Rec.GetPstdDocLinesToReverse();
end;
}
separator(Action1102601020)
{
}
action("Send IC Return Order")
{
AccessByPermission = TableData "IC G/L Account" = R;
ApplicationArea = Intercompany;
Caption = 'Send IC Return Order';
Image = IntercompanyOrder;
ToolTip = 'Send the document to the intercompany outbox or directly to the intercompany partner if automatic transaction sending is enabled.';
trigger OnAction()
var
ICInOutMgt: Codeunit ICInboxOutboxMgt;
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
if ApprovalsMgmt.PrePostApprovalCheckPurch(Rec) then
ICInOutMgt.SendPurchDoc(Rec, false);
end;
}
action("Delete Invoiced Orders")
{
ApplicationArea = PurchReturnOrder;
Caption = 'Delete Invoiced Orders';
Image = Delete;
RunObject = Report "Delete Invd Purch. Ret. Orders";
}
separator(Action1102601014)
{
}
}
group(Action8)
{
Caption = 'Warehouse';
Image = Warehouse;
action("Create Inventor&y Put-away/Pick")
{
AccessByPermission = TableData "Posted Invt. Pick Header" = R;
ApplicationArea = Warehouse;
Caption = 'Create Inventor&y Put-away/Pick';
Ellipsis = true;
Image = CreatePutawayPick;
ToolTip = 'Create an inventory put-away or inventory pick to handle items on the document according to a basic warehouse configuration that does not require warehouse receipt or shipment documents.';
trigger OnAction()
begin
Rec.PerformManualRelease();
Rec.CreateInvtPutAwayPick();
end;
}
action("Create &Warehouse Shipment")
{
AccessByPermission = TableData "Warehouse Shipment Header" = R;
ApplicationArea = Warehouse;
Caption = 'Create &Warehouse Shipment';
Image = NewShipment;
ToolTip = 'Create a warehouse shipment to start a pick a ship process according to an advanced warehouse configuration.';
trigger OnAction()
var
GetSourceDocOutbound: Codeunit "Get Source Doc. Outbound";
begin
Rec.PerformManualRelease();
GetSourceDocOutbound.CreateFromPurchaseReturnOrder(Rec);
end;
}
separator(Action1102601017)
{
}
}
group("P&osting")
{
Caption = 'P&osting';
Image = Post;
action(TestReport)
{
ApplicationArea = PurchReturnOrder;
Caption = 'Test Report';
Ellipsis = true;
Image = TestReport;
ToolTip = 'View a test report so that you can find and correct any errors before you perform the actual posting of the journal or document.';
trigger OnAction()
begin
ReportPrint.PrintPurchHeader(Rec);
end;
}
action(Post)
{
ApplicationArea = All;
Caption = 'P&ost';
Ellipsis = true;
Image = PostOrder;
ShortCutKey = 'F9';
ToolTip = 'Finalize the document or journal by posting the amounts and quantities to the related accounts in your company books.';
trigger OnAction()
begin
Rec.SendToPosting(Codeunit::"Purch.-Post (Yes/No)");
end;
}
action(PostSelected)
{
ApplicationArea = All;
Caption = 'Post S&elected';
Ellipsis = true;
Image = PostBatch;
ToolTip = 'Finalize the selected documents by posting the amounts and quantities to the related accounts in your company books.';
trigger OnAction()
var
PurchaseHeader: Record "Purchase Header";
PurchaseBatchPostMgt: Codeunit "Purchase Batch Post Mgt.";
BatchProcessingMgt: Codeunit "Batch Processing Mgt.";
begin
CurrPage.SetSelectionFilter(PurchaseHeader);
BatchProcessingMgt.SetParametersForPageID(Page::"Purchase Return Order List");
PurchaseBatchPostMgt.SetBatchProcessor(BatchProcessingMgt);
PurchaseBatchPostMgt.RunWithUI(PurchaseHeader, Rec.Count, ReadyToPostQst);
end;
}
action(Preview)
{
ApplicationArea = PurchReturnOrder;
Caption = 'Preview Posting';
Image = ViewPostedOrder;
ShortCutKey = 'Ctrl+Alt+F9';
ToolTip = 'Review the different types of entries that will be created when you post the document or journal.';
trigger OnAction()
var
SelectedPurchaseHeader: Record "Purchase Header";
PurchPostYesNo: Codeunit "Purch.-Post (Yes/No)";
begin
CurrPage.SetSelectionFilter(SelectedPurchaseHeader);
PurchPostYesNo.MessageIfPostingPreviewMultipleDocuments(SelectedPurchaseHeader, Rec."No.");
PurchPostYesNo.Preview(Rec);
end;
}
action(PostAndPrint)
{
ApplicationArea = PurchReturnOrder;
Caption = 'Post and &Print';
Ellipsis = true;
Image = PostPrint;
ShortCutKey = 'Shift+F9';
ToolTip = 'Finalize print the document or journal. The values and quantities are posted to the related accounts.';
trigger OnAction()
begin
Rec.SendToPosting(Codeunit::"Purch.-Post + Print");
end;
}
action(PostBatch)
{
ApplicationArea = Suite;
Caption = 'Post &Batch';
Ellipsis = true;
Image = PostBatch;
ToolTip = 'Post several documents at once. A report request window opens where you can specify which documents to post.';
trigger OnAction()
var
PurchaseHeader: Record "Purchase Header";
SelectionFilterManagement: Codeunit SelectionFilterManagement;
begin
CurrPage.SetSelectionFilter(PurchaseHeader);
PurchaseHeader.SetFilter("No.", SelectionFilterManagement.GetSelectionFilterForPurchaseHeader(PurchaseHeader));
REPORT.RunModal(REPORT::"Batch Post Purch. Ret. Orders", true, true, PurchaseHeader);
CurrPage.Update(false);
end;
}
action(RemoveFromJobQueue)
{
ApplicationArea = PurchReturnOrder;
Caption = 'Remove From Job Queue';
Image = RemoveLine;
ToolTip = 'Remove the scheduled processing of this record from the job queue.';
Visible = JobQueueActive;
trigger OnAction()
begin
Rec.CancelBackgroundPosting();
end;
}
}
group("Request Approval")
{
Caption = 'Request Approval';
action(SendApprovalRequest)
{
ApplicationArea = PurchReturnOrder;
Caption = 'Send A&pproval Request';
Enabled = not OpenApprovalEntriesExist;
Image = SendApprovalRequest;
ToolTip = 'Request approval of the document.';
trigger OnAction()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
if ApprovalsMgmt.CheckPurchaseApprovalPossible(Rec) then
ApprovalsMgmt.OnSendPurchaseDocForApproval(Rec);
end;
}
action(CancelApprovalRequest)
{
ApplicationArea = PurchReturnOrder;
Caption = 'Cancel Approval Re&quest';
Enabled = CanCancelApprovalForRecord;
Image = CancelApprovalRequest;
ToolTip = 'Cancel the approval request.';
trigger OnAction()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
ApprovalsMgmt.OnCancelPurchaseApprovalRequest(Rec);
end;
}
}
}
area(Promoted)
{
group(Category_Process)
{
Caption = 'Process', Comment = 'Generated from the PromotedActionCategories property index 1.';
actionref("Send IC Return Order_Promoted"; "Send IC Return Order")
{
}
actionref("Get Posted Doc&ument Lines to Reverse_Promoted"; "Get Posted Doc&ument Lines to Reverse")
{
}
actionref("Create &Warehouse Shipment_Promoted"; "Create &Warehouse Shipment")
{
}
}
group(Category_Category6)
{
Caption = 'Release', Comment = 'Generated from the PromotedActionCategories property index 5.';
ShowAs = SplitButton;
actionref(Release_Promoted; Release)
{
}
actionref(Reopen_Promoted; Reopen)
{
}
}
group(Category_Posting)
{
Caption = 'Posting';
ShowAs = SplitButton;
actionref(Post_Promoted; Post)
{
}
actionref(PostSelected_Promoted; PostSelected)
{
}
actionref(PostAndPrint_Promoted; PostAndPrint)
{
}
actionref(Preview_Promoted; Preview)
{
}
actionref(PostBatch_Promoted; PostBatch)
{
}
}
group("Category_Print/Send")
{
Caption = 'Print/Send';
actionref(Email_Promoted; Email)
{
}
actionref(Print_Promoted; Print)
{
}
actionref(Send_Promoted; Send)
{
}
actionref(AttachAsPDF_Promoted; AttachAsPDF)
{
}
}
group(Category_Category5)
{
Caption = 'Request Approval', Comment = 'Generated from the PromotedActionCategories property index 4.';
}
group(Category_Category4)
{
Caption = 'Return Order', Comment = 'Generated from the PromotedActionCategories property index 3.';
actionref(Dimensions_Promoted; Dimensions)
{
}
actionref(PurchaseOrderStatistics_Promoted; PurchaseOrderStatistics)
{
}
actionref("Co&mments_Promoted"; "Co&mments")
{
}
actionref(Approvals_Promoted; Approvals)
{
}
actionref("Return Shipments_Promoted"; "Return Shipments")
{
}
actionref("Cred&it Memos_Promoted"; "Cred&it Memos")
{
}
}
group(Category_Report)
{
Caption = 'Report', Comment = 'Generated from the PromotedActionCategories property index 2.';
}
}
}
trigger OnAfterGetRecord()
begin
StatusStyleTxt := Rec.GetStatusStyleText();
end;
trigger OnAfterGetCurrRecord()
begin
SetControlAppearance();
end;
trigger OnOpenPage()
var
PurchasesPayablesSetup: Record "Purchases & Payables Setup";
begin
Rec.SetSecurityFilterOnRespCenter();
JobQueueActive := PurchasesPayablesSetup.JobQueueActive();
Rec.CopyBuyFromVendorFilter();
end;
var
DocPrint: Codeunit "Document-Print";
ReportPrint: Codeunit "Test Report-Print";
JobQueueActive: Boolean;
OpenApprovalEntriesExist: Boolean;
CanCancelApprovalForRecord: Boolean;
ReadyToPostQst: Label 'The number of return orders that will be posted is %1. \Do you want to continue?', Comment = '%1 - selected count';
StatusStyleTxt: Text;
local procedure SetControlAppearance()
var
ApprovalsMgmt: Codeunit "Approvals Mgmt.";
begin
OpenApprovalEntriesExist := ApprovalsMgmt.HasOpenApprovalEntries(Rec.RecordId);
CanCancelApprovalForRecord := ApprovalsMgmt.CanCancelApprovalForRecord(Rec.RecordId);
end;
}