Page 95 Sales Quote Subform
- App
- Base Application
- Namespace
- Microsoft.Sales.Document
- Versions
- 17-28
- Source table
- 37
Procedures, 17Events, 21Obsolete, 1
Versions171819202122232425262728
Source29
Source in 29
src/Layers/W1/BaseApp/Sales/Document/SalesQuoteSubform.Page.al1650 lines, Copyright (c) Microsoft Corporation. MIT
// ------------------------------------------------------------------------------------------------
// Copyright (c) Microsoft Corporation. All rights reserved.
// Licensed under the MIT License. See License.txt in the project root for license information.
// ------------------------------------------------------------------------------------------------
namespace Microsoft.Sales.Document;
using Microsoft.Assembly.Document;
using Microsoft.Assembly.Setup;
using Microsoft.Finance.AllocationAccount;
using Microsoft.Finance.AllocationAccount.Sales;
using Microsoft.Finance.Currency;
using Microsoft.Finance.Dimension;
using Microsoft.Foundation.Attachment;
using Microsoft.Foundation.ExtendedText;
using Microsoft.Inventory.Availability;
using Microsoft.Inventory.BOM;
using Microsoft.Inventory.Item;
using Microsoft.Inventory.Item.Catalog;
using Microsoft.Inventory.Location;
using Microsoft.Pricing.Calculation;
using Microsoft.Sales.Pricing;
using Microsoft.Sales.Setup;
using Microsoft.Utilities;
using System.Environment.Configuration;
using System.Integration.Excel;
/// <summary>
/// Displays the line items subform for a sales quote document.
/// </summary>
page 95 "Sales Quote Subform"
{
AutoSplitKey = true;
Caption = 'Lines';
DelayedInsert = true;
LinksAllowed = false;
MultipleNewLines = true;
PageType = ListPart;
SourceTable = "Sales Line";
SourceTableView = where("Document Type" = filter(Quote));
layout
{
area(content)
{
repeater(Control1)
{
ShowCaption = false;
field(Type; Rec.Type)
{
ApplicationArea = Advanced;
ToolTip = 'Specifies the type of entity that will be posted for this sales line, such as Item, Resource, or G/L Account.';
Visible = not TypeAsTextFieldVisible;
trigger OnValidate()
begin
NoOnAfterValidate();
UpdateEditableOnRow();
UpdateTypeText();
DeltaUpdateTotals();
end;
}
field(FilteredTypeField; TypeAsText)
{
ApplicationArea = Basic, Suite;
Caption = 'Type';
Editable = CurrPageIsEditable;
LookupPageID = "Option Lookup List";
TableRelation = "Option Lookup Buffer"."Option Caption" where("Lookup Type" = const(Sales));
ToolTip = 'Specifies the type of transaction that will be posted with the document line. If you select Comment, then you can enter any text in the Description field, such as a message to a customer. ';
Visible = TypeAsTextFieldVisible;
trigger OnValidate()
begin
TempOptionLookupBuffer.SetCurrentType(Rec.Type.AsInteger());
if TempOptionLookupBuffer.AutoCompleteLookup(TypeAsText, TempOptionLookupBuffer."Lookup Type"::Sales) then
Rec.Validate(Type, TempOptionLookupBuffer.ID);
TempOptionLookupBuffer.ValidateOption(TypeAsText);
UpdateEditableOnRow();
UpdateTypeText();
DeltaUpdateTotals();
end;
}
field("No."; Rec."No.")
{
ApplicationArea = Basic, Suite;
ShowMandatory = not IsCommentLine;
ToolTip = 'Specifies the number of a general ledger account, item, resource, additional cost, or fixed asset, depending on the contents of the Type field.';
trigger OnValidate()
var
Item: Record "Item";
begin
Rec.ShowShortcutDimCode(ShortcutDimCode);
NoOnAfterValidate();
UpdateEditableOnRow();
UpdateTypeText();
DeltaUpdateTotals();
if Rec."Variant Code" = '' then
VariantCodeMandatory := Item.IsVariantMandatory(Rec.Type = Rec.Type::Item, Rec."No.");
CurrPage.Update();
end;
}
field("Item Reference No."; Rec."Item Reference No.")
{
AccessByPermission = tabledata "Item Reference" = R;
ApplicationArea = Suite, ItemReferences;
QuickEntry = false;
Visible = ItemReferenceVisible;
trigger OnLookup(var Text: Text): Boolean
var
ItemReferenceMgt: Codeunit "Item Reference Management";
begin
ItemReferenceMgt.SalesReferenceNoLookup(Rec);
NoOnAfterValidate();
UpdateEditableOnRow();
DeltaUpdateTotals();
OnItemReferenceNoOnLookup(Rec);
CurrPage.Update();
end;
trigger OnValidate()
begin
NoOnAfterValidate();
UpdateEditableOnRow();
DeltaUpdateTotals();
CurrPage.Update();
end;
}
field("Variant Code"; Rec."Variant Code")
{
ApplicationArea = Planning;
Visible = false;
ShowMandatory = VariantCodeMandatory;
trigger OnValidate()
var
Item: Record "Item";
begin
VariantCodeOnAfterValidate();
DeltaUpdateTotals();
if Rec."Variant Code" = '' then
VariantCodeMandatory := Item.IsVariantMandatory(Rec.Type = Rec.Type::Item, Rec."No.");
end;
}
field("Substitution Available"; Rec."Substitution Available")
{
ApplicationArea = Suite;
Visible = false;
}
field(Nonstock; Rec.Nonstock)
{
ApplicationArea = Basic, Suite;
Visible = false;
}
field("Gen. Bus. Posting Group"; Rec."Gen. Bus. Posting Group")
{
ApplicationArea = Basic, Suite;
Visible = false;
trigger OnValidate()
begin
DeltaUpdateTotals();
end;
}
field("Gen. Prod. Posting Group"; Rec."Gen. Prod. Posting Group")
{
ApplicationArea = Basic, Suite;
Visible = false;
trigger OnValidate()
begin
DeltaUpdateTotals();
end;
}
field("VAT Bus. Posting Group"; Rec."VAT Bus. Posting Group")
{
ApplicationArea = Basic, Suite;
Visible = false;
trigger OnValidate()
begin
ForceTotalsCalculation();
DeltaUpdateTotals();
end;
}
field("VAT Prod. Posting Group"; Rec."VAT Prod. Posting Group")
{
ApplicationArea = Basic, Suite;
Visible = false;
trigger OnValidate()
begin
ForceTotalsCalculation();
DeltaUpdateTotals();
end;
}
field(Description; Rec.Description)
{
ApplicationArea = Basic, Suite;
ShowMandatory = not IsCommentLine;
ToolTip = 'Specifies a description of the item you''re offering to the customer. The suggested text comes from the item, but you can change it to suit this document without changing the original description. If you''re adding a comment (you''ve chosen Comment in the Type field), this is where you enter it. For comments, leave the other fields on the line empty.';
trigger OnValidate()
begin
UpdateEditableOnRow();
Rec.RestoreLookupSelection();
if Rec."No." <> xRec."No." then
NoOnAfterValidate();
if Rec."No." = xRec."No." then
exit;
Rec.ShowShortcutDimCode(ShortcutDimCode);
UpdateTypeText();
DeltaUpdateTotals();
OnAfterValidateDescription(Rec, xRec);
end;
trigger OnAfterLookup(Selected: RecordRef)
begin
Rec.SaveLookupSelection(Selected);
end;
}
field("Description 2"; Rec."Description 2")
{
ApplicationArea = Basic, Suite;
Importance = Additional;
Visible = false;
}
field("Location Code"; Rec."Location Code")
{
ApplicationArea = Location;
Editable = not IsBlankNumber;
Enabled = not IsBlankNumber;
trigger OnValidate()
begin
LocationCodeOnAfterValidate();
DeltaUpdateTotals();
end;
}
field(Quantity; Rec.Quantity)
{
ApplicationArea = Basic, Suite;
BlankZero = true;
Editable = not IsBlankNumber;
Enabled = not IsBlankNumber;
ShowMandatory = (Rec.Type <> Rec.Type::" ") and (Rec."No." <> '');
trigger OnValidate()
begin
CurrPage.SaveRecord();
QuantityOnAfterValidate();
if SalesSetup."Calc. Inv. Discount" and (Rec.Quantity = 0) then
CurrPage.Update(false);
end;
}
field("Qty. to Assemble to Order"; Rec."Qty. to Assemble to Order")
{
ApplicationArea = Assembly;
Editable = not IsBlankNumber;
Enabled = not IsBlankNumber;
StyleExpr = ItemChargeStyleExpression;
trigger OnDrillDown()
begin
Rec.ShowAsmToOrderLines();
end;
trigger OnValidate()
begin
CurrPage.Update(true);
end;
}
field("Unit of Measure Code"; Rec."Unit of Measure Code")
{
ApplicationArea = Basic, Suite;
Editable = UnitofMeasureCodeIsChangeable;
Enabled = UnitofMeasureCodeIsChangeable;
trigger OnValidate()
begin
UnitofMeasureCodeOnAfterValidate();
end;
}
field("Unit of Measure"; Rec."Unit of Measure")
{
ApplicationArea = Suite;
Visible = false;
}
field("Unit Cost (LCY)"; Rec."Unit Cost (LCY)")
{
ApplicationArea = Basic, Suite;
ToolTip = 'Specifies the unit cost of the item on the line.';
Visible = false;
}
field(PriceExists; Rec.PriceExists())
{
ApplicationArea = Basic, Suite;
Caption = 'Sales Price Exists';
Editable = false;
ToolTip = 'Specifies that there is a specific price for this customer.';
Visible = false;
}
field("Unit Price"; Rec."Unit Price")
{
ApplicationArea = Basic, Suite;
BlankZero = true;
Editable = not IsBlankNumber;
Enabled = not IsBlankNumber;
ShowMandatory = (Rec.Type <> Rec.Type::" ") and (Rec."No." <> '');
trigger OnValidate()
begin
DeltaUpdateTotals();
end;
}
field("Tax Liable"; Rec."Tax Liable")
{
ApplicationArea = SalesTax;
Editable = false;
Visible = false;
}
field("Tax Area Code"; Rec."Tax Area Code")
{
ApplicationArea = SalesTax;
Visible = false;
trigger OnValidate()
begin
DeltaUpdateTotals();
end;
}
field("Tax Group Code"; Rec."Tax Group Code")
{
ApplicationArea = SalesTax;
Editable = not IsCommentLine;
Enabled = not IsCommentLine;
ShowMandatory = Rec."Tax Area Code" <> '';
trigger OnValidate()
begin
DeltaUpdateTotals();
end;
}
field("Line Discount %"; Rec."Line Discount %")
{
ApplicationArea = Basic, Suite;
BlankZero = true;
Editable = not IsBlankNumber;
Enabled = not IsBlankNumber;
trigger OnValidate()
begin
DeltaUpdateTotals();
end;
}
field("Line Amount"; Rec."Line Amount")
{
ApplicationArea = Basic, Suite;
BlankZero = true;
Editable = not IsBlankNumber;
Enabled = not IsBlankNumber;
ShowMandatory = (Rec.Type <> Rec.Type::" ") and (Rec."No." <> '');
trigger OnValidate()
begin
DeltaUpdateTotals();
end;
}
field(LineDiscExists; Rec.LineDiscExists())
{
ApplicationArea = Basic, Suite;
Caption = 'Sales Line Disc. Exists';
Editable = false;
ToolTip = 'Specifies that there is a specific discount for this customer.';
Visible = false;
}
field("Line Discount Amount"; Rec."Line Discount Amount")
{
ApplicationArea = Basic, Suite;
Visible = false;
trigger OnValidate()
begin
DeltaUpdateTotals();
end;
}
field("Allow Invoice Disc."; Rec."Allow Invoice Disc.")
{
ApplicationArea = Basic, Suite;
Visible = false;
trigger OnValidate()
begin
CurrPage.SaveRecord();
AmountWithDiscountAllowed := DocumentTotals.CalcTotalSalesAmountOnlyDiscountAllowed(Rec);
InvoiceDiscountAmount := Round(AmountWithDiscountAllowed * InvoiceDiscountPct / 100, Currency."Amount Rounding Precision");
ValidateInvoiceDiscountAmount();
end;
}
field("Inv. Discount Amount"; Rec."Inv. Discount Amount")
{
ApplicationArea = Basic, Suite;
Editable = false;
Visible = false;
trigger OnValidate()
begin
UpdatePage();
DeltaUpdateTotals();
end;
}
field("Allocation Account No."; Rec."Selected Alloc. Account No.")
{
ApplicationArea = All;
Caption = 'Allocation Account No.';
Visible = UseAllocationAccountNumber;
trigger OnValidate()
var
SalesAllocAccMgt: Codeunit "Sales Alloc. Acc. Mgt.";
begin
SalesAllocAccMgt.VerifySelectedAllocationAccountNo(Rec);
end;
}
field("Allow Item Charge Assignment"; Rec."Allow Item Charge Assignment")
{
ApplicationArea = ItemCharges;
Visible = false;
}
field("Qty. to Assign"; Rec."Qty. to Assign")
{
ApplicationArea = ItemCharges;
trigger OnDrillDown()
begin
CurrPage.SaveRecord();
Rec.ShowItemChargeAssgnt();
UpdateForm(false);
end;
}
field("Qty. Assigned"; Rec."Qty. Assigned")
{
ApplicationArea = ItemCharges;
BlankZero = true;
ToolTip = 'Specifies how much of the item charge has been assigned.';
trigger OnDrillDown()
begin
CurrPage.SaveRecord();
Rec.ShowItemChargeAssgnt();
UpdateForm(false);
end;
}
field("Shipping Agent Code"; Rec."Shipping Agent Code")
{
ApplicationArea = Suite;
Visible = false;
}
field("Shipping Agent Service Code"; Rec."Shipping Agent Service Code")
{
ApplicationArea = Suite;
Visible = false;
}
field("Work Type Code"; Rec."Work Type Code")
{
ApplicationArea = Jobs;
Visible = false;
}
field("Blanket Order No."; Rec."Blanket Order No.")
{
ApplicationArea = Suite;
Visible = false;
}
field("Blanket Order Line No."; Rec."Blanket Order Line No.")
{
ApplicationArea = Suite;
Visible = false;
}
field("Appl.-to Item Entry"; Rec."Appl.-to Item Entry")
{
ApplicationArea = Basic, Suite;
Visible = false;
}
field("Shortcut Dimension 1 Code"; Rec."Shortcut Dimension 1 Code")
{
ApplicationArea = Dimensions;
Visible = DimVisible1;
}
field("Shortcut Dimension 2 Code"; Rec."Shortcut Dimension 2 Code")
{
ApplicationArea = Dimensions;
Visible = DimVisible2;
}
field(ShortcutDimCode3; ShortcutDimCode[3])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,3';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(3),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible3;
trigger OnValidate()
begin
ValidateShortcutDimension(3);
end;
}
field(ShortcutDimCode4; ShortcutDimCode[4])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,4';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(4),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible4;
trigger OnValidate()
begin
ValidateShortcutDimension(4);
end;
}
field(ShortcutDimCode5; ShortcutDimCode[5])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,5';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(5),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible5;
trigger OnValidate()
begin
ValidateShortcutDimension(5);
end;
}
field(ShortcutDimCode6; ShortcutDimCode[6])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,6';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(6),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible6;
trigger OnValidate()
begin
ValidateShortcutDimension(6);
end;
}
field(ShortcutDimCode7; ShortcutDimCode[7])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,7';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(7),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible7;
trigger OnValidate()
begin
ValidateShortcutDimension(7);
end;
}
field(ShortcutDimCode8; ShortcutDimCode[8])
{
ApplicationArea = Dimensions;
CaptionClass = '1,2,8';
TableRelation = "Dimension Value".Code where("Global Dimension No." = const(8),
"Dimension Value Type" = const(Standard),
Blocked = const(false));
Visible = DimVisible8;
trigger OnValidate()
begin
ValidateShortcutDimension(8);
end;
}
field("Gross Weight"; Rec."Gross Weight")
{
Caption = 'Unit Gross Weight';
ApplicationArea = Basic, Suite;
Visible = false;
}
field("Net Weight"; Rec."Net Weight")
{
Caption = 'Unit Net Weight';
ApplicationArea = Basic, Suite;
Visible = false;
}
field("Unit Volume"; Rec."Unit Volume")
{
ApplicationArea = Basic, Suite;
Visible = false;
}
field("Units per Parcel"; Rec."Units per Parcel")
{
ApplicationArea = Basic, Suite;
Visible = false;
}
}
group(Control53)
{
ShowCaption = false;
group(Control49)
{
ShowCaption = false;
field("Subtotal Excl. VAT"; TotalSalesLine."Line Amount")
{
ApplicationArea = Basic, Suite;
AutoFormatExpression = Currency.Code;
AutoFormatType = 1;
CaptionClass = DocumentTotals.GetTotalLineAmountWithVATAndCurrencyCaption(Currency.Code, TotalSalesHeader."Prices Including VAT");
Caption = 'Subtotal Excl. VAT';
Editable = false;
ToolTip = 'Specifies the sum of the value in the Line Amount Excl. VAT field on all lines in the document.';
}
field("Invoice Discount Amount"; InvoiceDiscountAmount)
{
ApplicationArea = Basic, Suite;
AutoFormatExpression = Currency.Code;
AutoFormatType = 1;
CaptionClass = DocumentTotals.GetInvoiceDiscAmountWithVATAndCurrencyCaption(Rec.FieldCaption("Inv. Discount Amount"), Currency.Code);
Caption = 'Invoice Discount Amount';
Editable = InvDiscAmountEditable;
ToolTip = 'Specifies a discount amount that is deducted from the value of the Total Incl. VAT field, based on sales lines where the Allow Invoice Disc. field is selected. You can enter or change the amount manually.';
trigger OnValidate()
begin
ValidateInvoiceDiscountAmount();
end;
}
field("Invoice Disc. Pct."; InvoiceDiscountPct)
{
ApplicationArea = Basic, Suite;
AutoFormatType = 0;
Caption = 'Invoice Discount %';
DecimalPlaces = 0 : 3;
Editable = InvDiscAmountEditable;
ToolTip = 'Specifies a discount percentage that is applied to the invoice, based on sales lines where the Allow Invoice Disc. field is selected. The percentage and criteria are defined in the Customer Invoice Discounts page, but you can enter or change the percentage manually.';
trigger OnValidate()
begin
AmountWithDiscountAllowed := DocumentTotals.CalcTotalSalesAmountOnlyDiscountAllowed(Rec);
InvoiceDiscountAmount := Round(AmountWithDiscountAllowed * InvoiceDiscountPct / 100, Currency."Amount Rounding Precision");
ValidateInvoiceDiscountAmount();
end;
}
}
group(Control35)
{
ShowCaption = false;
field("Total Amount Excl. VAT"; TotalSalesLine.Amount)
{
ApplicationArea = Basic, Suite;
AutoFormatExpression = Currency.Code;
AutoFormatType = 1;
CaptionClass = DocumentTotals.GetTotalExclVATCaption(Currency.Code);
Caption = 'Total Amount Excl. VAT';
DrillDown = false;
Editable = false;
ToolTip = 'Specifies the sum of the value in the Line Amount Excl. VAT field on all lines in the document minus any discount amount in the Invoice Discount Amount field.';
}
field("Total VAT Amount"; VATAmount)
{
ApplicationArea = Basic, Suite;
AutoFormatExpression = Currency.Code;
AutoFormatType = 1;
CaptionClass = DocumentTotals.GetTotalVATCaption(Currency.Code);
Caption = 'Total VAT';
Editable = false;
ToolTip = 'Specifies the sum of VAT amounts on all lines in the document.';
}
field("Total Amount Incl. VAT"; TotalSalesLine."Amount Including VAT")
{
ApplicationArea = Basic, Suite;
AutoFormatExpression = Currency.Code;
AutoFormatType = 1;
CaptionClass = DocumentTotals.GetTotalInclVATCaption(Currency.Code);
Caption = 'Total Amount Incl. VAT';
Editable = false;
ToolTip = 'Specifies the sum of the value in the Line Amount Incl. VAT field on all lines in the document minus any discount amount in the Invoice Discount Amount field.';
}
}
}
}
}
actions
{
area(processing)
{
action(SelectMultiItems)
{
AccessByPermission = TableData Item = R;
ApplicationArea = Basic, Suite;
Caption = 'Select items';
Ellipsis = true;
Image = NewItem;
ToolTip = 'Add two or more items from the full list of your inventory items.';
trigger OnAction()
begin
Rec.SelectMultipleItems();
end;
}
action(InsertExtTexts)
{
AccessByPermission = TableData "Extended Text Header" = R;
ApplicationArea = Suite;
Caption = 'Insert &Ext. Texts';
Image = Text;
ToolTip = 'Insert the extended item description that is set up for the item that is being processed on the line.';
trigger OnAction()
begin
InsertExtendedText(true);
end;
}
action(Dimensions)
{
AccessByPermission = TableData Dimension = R;
ApplicationArea = Dimensions;
Caption = 'Dimensions';
Image = Dimensions;
ShortCutKey = 'Alt+D';
ToolTip = 'View or edit dimensions, such as area, project, or department, that you can assign to sales and purchase documents to distribute costs and analyze transaction history.';
trigger OnAction()
begin
Rec.ShowDimensions();
end;
}
group("&Line")
{
Caption = '&Line';
Image = Line;
group("Item Availability by")
{
Enabled = Rec.Type = Rec.Type::Item;
Caption = 'Item Availability by';
Image = ItemAvailability;
action("Event")
{
ApplicationArea = Basic, Suite;
Caption = 'Event';
Image = "Event";
ToolTip = 'View how the actual and the projected available balance of an item will develop over time according to supply and demand events.';
trigger OnAction()
begin
SalesAvailabilityMgt.ShowItemAvailabilityFromSalesLine(Rec, "Item Availability Type"::"Event");
end;
}
action(Period)
{
ApplicationArea = Basic, Suite;
Caption = 'Period';
Image = Period;
ToolTip = 'Show the projected quantity of the item over time according to time periods, such as day, week, or month.';
trigger OnAction()
begin
SalesAvailabilityMgt.ShowItemAvailabilityFromSalesLine(Rec, "Item Availability Type"::Period);
end;
}
action(Variant)
{
ApplicationArea = Planning;
Caption = 'Variant';
Image = ItemVariant;
ToolTip = 'View or edit the item''s variants. Instead of setting up each color of an item as a separate item, you can set up the various colors as variants of the item.';
trigger OnAction()
begin
SalesAvailabilityMgt.ShowItemAvailabilityFromSalesLine(Rec, "Item Availability Type"::Variant);
end;
}
action(Location)
{
AccessByPermission = TableData Location = R;
ApplicationArea = Location;
Caption = 'Location';
Image = Warehouse;
ToolTip = 'View the actual and projected quantity of the item per location.';
trigger OnAction()
begin
SalesAvailabilityMgt.ShowItemAvailabilityFromSalesLine(Rec, "Item Availability Type"::Location);
end;
}
action(Lot)
{
ApplicationArea = ItemTracking;
Caption = 'Lot';
Image = LotInfo;
RunObject = Page "Item Availability by Lot No.";
RunPageLink = "No." = field("No."),
"Location Filter" = field("Location Code"),
"Variant Filter" = field("Variant Code");
ToolTip = 'View the current and projected quantity of the item in each lot.';
}
action("BOM Level")
{
AccessByPermission = TableData "BOM Buffer" = R;
ApplicationArea = Assembly;
Caption = 'BOM Level';
Image = BOMLevel;
ToolTip = 'View availability figures for items on bills of materials that show how many units of a parent item you can make based on the availability of child items.';
trigger OnAction()
begin
SalesAvailabilityMgt.ShowItemAvailabilityFromSalesLine(Rec, "Item Availability Type"::BOM);
end;
}
}
action("Select Item Substitution")
{
ApplicationArea = Suite;
Caption = 'Select Item Substitution';
Image = SelectItemSubstitution;
ToolTip = 'Select another item that has been set up to be sold instead of the original item if it is unavailable.';
trigger OnAction()
begin
Rec.ShowItemSub();
end;
}
action("Co&mments")
{
ApplicationArea = Comments;
Caption = 'Co&mments';
Image = ViewComments;
ToolTip = 'View or add comments for the record.';
trigger OnAction()
begin
Rec.ShowLineComments();
end;
}
action("Item Charge &Assignment")
{
AccessByPermission = TableData "Item Charge" = R;
ApplicationArea = ItemCharges;
Caption = 'Item Charge &Assignment';
Enabled = Rec.Type = Rec.Type::"Charge (Item)";
Image = ItemCosts;
ToolTip = 'Record additional direct costs, for example for freight. This action is available only for Charge (Item) line types.';
trigger OnAction()
begin
ItemChargeAssgnt();
SetItemChargeFieldsStyle();
end;
}
action("Item &Tracking Lines")
{
ApplicationArea = ItemTracking;
Caption = 'Item &Tracking Lines';
Image = ItemTrackingLines;
ShortCutKey = 'Ctrl+Alt+I';
Enabled = Rec.Type = Rec.Type::Item;
ToolTip = 'View or edit serial, lot and package numbers for the selected item. This action is available only for lines that contain an item.';
trigger OnAction()
var
Item: Record Item;
begin
Item.Get(Rec."No.");
Item.TestField("Assembly Policy", Item."Assembly Policy"::"Assemble-to-Stock");
Rec.TestField("Qty. to Asm. to Order (Base)", 0);
Rec.OpenItemTrackingLines();
end;
}
action("Select Nonstoc&k Items")
{
AccessByPermission = TableData "Nonstock Item" = R;
ApplicationArea = Basic, Suite;
Caption = 'Select Ca&talog Items';
Image = NonStockItem;
ToolTip = 'View the list of catalog items that exist in the system. ';
trigger OnAction()
begin
ShowNonstockItems();
end;
}
action(DocAttach)
{
ApplicationArea = All;
Caption = 'Attachments';
Image = Attach;
ToolTip = 'Add a file as an attachment. You can attach images as well as documents.';
trigger OnAction()
var
DocumentAttachmentDetails: Page "Document Attachment Details";
RecRef: RecordRef;
begin
RecRef.GetTable(Rec);
DocumentAttachmentDetails.OpenForRecRef(RecRef);
DocumentAttachmentDetails.RunModal();
end;
}
group("Assemble to Order")
{
Caption = 'Assemble to Order';
Image = AssemblyBOM;
action("Assemble-to-Order Lines")
{
AccessByPermission = TableData "BOM Component" = R;
ApplicationArea = Assembly;
Caption = 'Assemble-to-Order Lines';
ToolTip = 'View any linked assembly order lines if the documents represents an assemble-to-order sale.';
trigger OnAction()
begin
Rec.ShowAsmToOrderLines();
end;
}
action("Roll Up &Price")
{
AccessByPermission = TableData "BOM Component" = R;
ApplicationArea = Assembly;
Caption = 'Roll Up &Price';
Ellipsis = true;
ToolTip = 'Update the unit price of the assembly item according to any changes that you have made to the assembly components.';
trigger OnAction()
begin
Rec.RollupAsmPrice();
CalculateTotals();
end;
}
action("Roll Up &Cost")
{
AccessByPermission = TableData "BOM Component" = R;
ApplicationArea = Assembly;
Caption = 'Roll Up &Cost';
Ellipsis = true;
ToolTip = 'Update the unit cost of the assembly item according to any changes that you have made to the assembly components.';
trigger OnAction()
begin
Rec.RollUpAsmCost();
CalculateTotals();
end;
}
}
}
group("F&unctions")
{
Caption = 'F&unctions';
Image = "Action";
action("Get &Price")
{
AccessByPermission = TableData "Sales Price" = R;
ApplicationArea = Basic, Suite;
Caption = 'Get &Price';
Ellipsis = true;
Image = Price;
ToolTip = 'Insert the lowest possible price in the Unit Price field according to any special price that you have set up.';
Visible = not ExtendedPriceEnabled;
trigger OnAction()
begin
Rec.PickPrice();
end;
}
action("Get Li&ne Discount")
{
AccessByPermission = TableData "Sales Line Discount" = R;
ApplicationArea = Basic, Suite;
Caption = 'Get Li&ne Discount';
Ellipsis = true;
Image = LineDiscount;
ToolTip = 'Insert the best possible discount in the Line Discount field according to any special discounts that you have set up.';
Visible = not ExtendedPriceEnabled;
trigger OnAction()
begin
Rec.PickDiscount();
end;
}
action(GetPrice)
{
AccessByPermission = TableData "Sales Price Access" = R;
ApplicationArea = Basic, Suite;
Caption = 'Get &Price';
Ellipsis = true;
Image = Price;
Visible = ExtendedPriceEnabled;
ToolTip = 'Insert the lowest possible price in the Unit Price field according to any special price that you have set up.';
trigger OnAction()
begin
Rec.PickPrice();
end;
}
action(GetLineDiscount)
{
AccessByPermission = TableData "Sales Discount Access" = R;
ApplicationArea = Basic, Suite;
Caption = 'Get Li&ne Discount';
Ellipsis = true;
Image = LineDiscount;
Visible = ExtendedPriceEnabled;
ToolTip = 'Insert the best possible discount in the Line Discount field according to any special discounts that you have set up.';
trigger OnAction()
begin
Rec.PickDiscount();
end;
}
action("E&xplode BOM")
{
AccessByPermission = TableData "BOM Component" = R;
ApplicationArea = Suite;
Caption = 'E&xplode BOM';
Image = ExplodeBOM;
Enabled = Rec.Type = Rec.Type::Item;
ToolTip = 'Add a line for each component on the bill of materials for the selected item. For example, this is useful for selling the parent item as a kit. CAUTION: The line for the parent item will be deleted and only its description will display. To undo this action, delete the component lines and add a line for the parent item again. This action is available only for lines that contain an item.';
trigger OnAction()
begin
ExplodeBOM();
end;
}
action(RedistributeAccAllocations)
{
ApplicationArea = All;
Caption = 'Redistribute Account Allocations';
Image = EditList;
#pragma warning disable AA0219
ToolTip = 'Use this action to redistribute the account allocations for this line.';
#pragma warning restore AA0219
trigger OnAction()
var
AllocAccManualOverride: Page "Redistribute Acc. Allocations";
begin
if ((Rec."Type" <> Rec."Type"::"Allocation Account") and (Rec."Selected Alloc. Account No." = '')) then
Error(ActionOnlyAllowedForAllocationAccountsErr);
AllocAccManualOverride.SetParentSystemId(Rec.SystemId);
AllocAccManualOverride.SetParentTableId(Database::"Sales Line");
AllocAccManualOverride.RunModal();
end;
}
action(ReplaceAllocationAccountWithLines)
{
ApplicationArea = All;
Caption = 'Generate lines from Allocation Account Line';
Image = CreateLinesFromJob;
#pragma warning disable AA0219
ToolTip = 'Use this action to replace the Allocation Account line with the actual lines that would be generated from the line itself.';
#pragma warning restore AA0219
trigger OnAction()
var
SalesAllocAccMgt: Codeunit "Sales Alloc. Acc. Mgt.";
begin
if ((Rec."Type" <> Rec."Type"::"Allocation Account") and (Rec."Selected Alloc. Account No." = '')) then
Error(ActionOnlyAllowedForAllocationAccountsErr);
SalesAllocAccMgt.CreateLinesFromAllocationAccountLine(Rec);
Rec.Delete();
CurrPage.Update(false);
end;
}
}
group("Page")
{
Caption = 'Page';
action(EditInExcel)
{
ApplicationArea = Basic, Suite;
Caption = 'Edit in Excel';
Image = Excel;
Visible = IsSaaSExcelAddinEnabled;
ToolTip = 'Send the data in the sub page to an Excel file for analysis or editing';
AccessByPermission = System "Allow Action Export To Excel" = X;
trigger OnAction()
var
EditinExcel: Codeunit "Edit in Excel";
EditinExcelFilters: Codeunit "Edit in Excel Filters";
begin
EditinExcelFilters.AddFieldV2('Document_No', Enum::"Edit in Excel Filter Type"::Equal, Rec."Document No.", Enum::"Edit in Excel Edm Type"::"Edm.String");
EditinExcel.EditPageInExcel(
'Sales_QuoteSalesLines',
Page::"Sales Quote Subform",
EditinExcelFilters,
StrSubstNo(ExcelFileNameTxt, Rec."Document No."));
end;
}
}
}
}
trigger OnAfterGetCurrRecord()
begin
GetTotalSalesHeader();
CalculateTotals();
UpdateEditableOnRow();
UpdateTypeText();
SetItemChargeFieldsStyle();
end;
trigger OnAfterGetRecord()
var
Item: Record Item;
begin
Rec.ShowShortcutDimCode(ShortcutDimCode);
UpdateEditableOnRow();
UpdateTypeText();
SetItemChargeFieldsStyle();
if Rec."Variant Code" = '' then
VariantCodeMandatory := Item.IsVariantMandatory(Rec.Type = Rec.Type::Item, Rec."No.");
end;
trigger OnDeleteRecord(): Boolean
var
SalesLineReserve: Codeunit "Sales Line-Reserve";
begin
if Rec.Quantity <> 0 then
if Rec.ItemExists(Rec."No.") then begin
if not SalesLineReserve.DeleteLineConfirm(Rec) then
exit(false);
OnDeleteRecordOnBeforeSalesLineReserveDeleteLine(Rec);
SalesLineReserve.DeleteLine(Rec);
end;
DocumentTotals.SalesDocTotalsNotUpToDate();
end;
trigger OnFindRecord(Which: Text): Boolean
begin
DocumentTotals.SalesCheckAndClearTotals(Rec, xRec, TotalSalesLine, VATAmount, InvoiceDiscountAmount, InvoiceDiscountPct);
exit(Rec.Find(Which));
end;
trigger OnInit()
var
ApplicationAreaMgmtFacade: Codeunit "Application Area Mgmt. Facade";
begin
SalesSetup.Get();
Currency.InitRoundingPrecision();
TempOptionLookupBuffer.FillLookupBuffer(TempOptionLookupBuffer."Lookup Type"::Sales);
TypeAsTextFieldVisible := ApplicationAreaMgmtFacade.IsFoundationEnabled() and not ApplicationAreaMgmtFacade.IsAdvancedEnabled();
end;
trigger OnModifyRecord(): Boolean
begin
DocumentTotals.SalesCheckIfDocumentChanged(Rec, xRec);
end;
trigger OnNewRecord(BelowxRec: Boolean)
begin
Rec.InitType();
OnNewRecordOnAfterInitType(Rec, xRec, BelowxRec);
SetDefaultType();
Clear(ShortcutDimCode);
UpdateTypeText();
end;
trigger OnOpenPage()
var
AllocationAccountMgt: Codeunit "Allocation Account Mgt.";
begin
UseAllocationAccountNumber := AllocationAccountMgt.UseAllocationAccountNoField();
SetOpenPage();
SetDimensionsVisibility();
SetItemReferenceVisibility();
end;
var
SalesSetup: Record "Sales & Receivables Setup";
TempOptionLookupBuffer: Record "Option Lookup Buffer" temporary;
TransferExtendedText: Codeunit "Transfer Extended Text";
SalesAvailabilityMgt: Codeunit "Sales Availability Mgt.";
SalesCalcDiscByType: Codeunit "Sales - Calc Discount By Type";
AmountWithDiscountAllowed: Decimal;
VariantCodeMandatory: Boolean;
CurrPageIsEditable: Boolean;
IsSaaSExcelAddinEnabled: Boolean;
ExtendedPriceEnabled: Boolean;
TypeAsText: Text[30];
TypeAsTextFieldVisible: Boolean;
UseAllocationAccountNumber: Boolean;
ActionOnlyAllowedForAllocationAccountsErr: Label 'This action is only available for lines that have Allocation Account set as Type.';
ExcelFileNameTxt: Label 'Sales Quote %1 - Lines', Comment = '%1 = document number, ex. 10000';
protected var
Currency: Record Currency;
TotalSalesHeader: Record "Sales Header";
TotalSalesLine: Record "Sales Line";
DocumentTotals: Codeunit "Document Totals";
ShortcutDimCode: array[8] of Code[20];
DimVisible1: Boolean;
DimVisible2: Boolean;
DimVisible3: Boolean;
DimVisible4: Boolean;
DimVisible5: Boolean;
DimVisible6: Boolean;
DimVisible7: Boolean;
DimVisible8: Boolean;
InvoiceDiscountAmount: Decimal;
InvoiceDiscountPct: Decimal;
InvDiscAmountEditable: Boolean;
IsBlankNumber: Boolean;
IsCommentLine: Boolean;
SuppressTotals: Boolean;
ItemReferenceVisible: Boolean;
UnitofMeasureCodeIsChangeable: Boolean;
ItemChargeStyleExpression: Text;
VATAmount: Decimal;
local procedure SetOpenPage()
var
ServerSetting: Codeunit "Server Setting";
PriceCalculationMgt: Codeunit "Price Calculation Mgt.";
begin
OnBeforeSetOpenPage();
IsSaaSExcelAddinEnabled := ServerSetting.GetIsSaasExcelAddinEnabled();
SuppressTotals := CurrentClientType() = ClientType::ODataV4;
ExtendedPriceEnabled := PriceCalculationMgt.IsExtendedPriceCalculationEnabled();
end;
/// <summary>
/// Approves and calculates the invoice discount for the current line.
/// </summary>
procedure ApproveCalcInvDisc()
begin
CODEUNIT.Run(CODEUNIT::"Sales-Disc. (Yes/No)", Rec);
DocumentTotals.SalesDocTotalsNotUpToDate();
end;
local procedure ValidateInvoiceDiscountAmount()
var
SalesHeader: Record "Sales Header";
begin
if SuppressTotals then
exit;
SalesHeader.Get(Rec."Document Type", Rec."Document No.");
SalesCalcDiscByType.ApplyInvDiscBasedOnAmt(InvoiceDiscountAmount, SalesHeader);
DocumentTotals.SalesDocTotalsNotUpToDate();
CurrPage.Update(false);
end;
/// <summary>
/// Calculates the invoice discount for the current line.
/// </summary>
procedure CalcInvDisc()
var
SalesCalcDiscount: Codeunit "Sales-Calc. Discount";
begin
SalesCalcDiscount.CalculateInvoiceDiscountOnLine(Rec);
DocumentTotals.SalesDocTotalsNotUpToDate();
end;
/// <summary>
/// Explodes the bill of materials for the current item line.
/// </summary>
procedure ExplodeBOM()
begin
CODEUNIT.Run(CODEUNIT::"Sales-Explode BOM", Rec);
DocumentTotals.SalesDocTotalsNotUpToDate();
end;
/// <summary>
/// Inserts extended text for the current line if available.
/// </summary>
/// <param name="Unconditionally">Whether to insert text without conditions.</param>
procedure InsertExtendedText(Unconditionally: Boolean)
begin
if not Unconditionally and (Rec."No." = xRec."No.") then
exit;
OnBeforeInsertExtendedText(Rec);
if TransferExtendedText.SalesCheckIfAnyExtText(Rec, Unconditionally) then begin
CurrPage.SaveRecord();
Commit();
TransferExtendedText.InsertSalesExtText(Rec);
end;
if TransferExtendedText.MakeUpdate() then
UpdateForm(true);
end;
local procedure ShowNonstockItems()
begin
Rec.ShowNonstock();
OnAfterShowNonstockItems(Rec);
end;
local procedure ItemChargeAssgnt()
begin
Rec.ShowItemChargeAssgnt();
end;
/// <summary>
/// Updates the current page with optional record save.
/// </summary>
/// <param name="SetSaveRecord">Whether to save the record before updating.</param>
procedure UpdateForm(SetSaveRecord: Boolean)
begin
CurrPage.Update(SetSaveRecord);
end;
/// <summary>
/// Handles post-validation logic after the No. field is validated.
/// </summary>
procedure NoOnAfterValidate()
begin
OnBeforeNoOnAfterValidate(Rec, xRec);
InsertExtendedText(false);
if (Rec.Type = Rec.Type::"Charge (Item)") and (Rec."No." <> xRec."No.") and
(xRec."No." <> '')
then
CurrPage.SaveRecord();
OnAfterNoOnAfterValidate(Rec, xRec);
SaveAndAutoAsmToOrder();
end;
protected procedure LocationCodeOnAfterValidate()
begin
SaveAndAutoAsmToOrder();
end;
local procedure VariantCodeOnAfterValidate()
begin
SaveAndAutoAsmToOrder();
end;
protected procedure QuantityOnAfterValidate()
begin
if Rec.Reserve = Rec.Reserve::Always then begin
CurrPage.SaveRecord();
Rec.AutoReserve();
end;
OnQuantityOnAfterValidateOnBeforeDeltaUpdateTotals(Rec, xRec);
DeltaUpdateTotals();
OnAfterQuantityOnAfterValidate(Rec, xRec);
end;
protected procedure UnitofMeasureCodeOnAfterValidate()
begin
if Rec.Reserve = Rec.Reserve::Always then begin
CurrPage.SaveRecord();
Rec.AutoReserve();
end;
OnUnitofMeasureCodeOnAfterValidateOnBeforeDeltaUpdateTotals(Rec, xRec);
DeltaUpdateTotals();
end;
local procedure SaveAndAutoAsmToOrder()
begin
if (Rec.Type = Rec.Type::Item) and Rec.IsAsmToOrderRequired() then begin
CurrPage.SaveRecord();
Rec.AutoAsmToOrder();
end;
end;
/// <summary>
/// Updates the editable state of fields on the current row.
/// </summary>
procedure UpdateEditableOnRow()
begin
IsCommentLine := not Rec.HasTypeToFillMandatoryFields();
IsBlankNumber := IsCommentLine;
UnitofMeasureCodeIsChangeable := not IsCommentLine;
CurrPageIsEditable := CurrPage.Editable;
InvDiscAmountEditable :=
CurrPageIsEditable and not SalesSetup."Calc. Inv. Discount" and
(TotalSalesHeader.Status = TotalSalesHeader.Status::Open);
OnAfterUpdateEditableOnRow(Rec, IsCommentLine, IsBlankNumber);
end;
local procedure UpdatePage()
var
SalesHeader: Record "Sales Header";
begin
CurrPage.Update();
SalesHeader.Get(Rec."Document Type", Rec."Document No.");
SalesCalcDiscByType.ApplyDefaultInvoiceDiscount(TotalSalesHeader."Invoice Discount Amount", SalesHeader);
end;
local procedure GetTotalSalesHeader()
begin
DocumentTotals.GetTotalSalesHeaderAndCurrency(Rec, TotalSalesHeader, Currency);
end;
/// <summary>
/// Clears the total sales header variable.
/// </summary>
procedure ClearTotalSalesHeader();
begin
Clear(TotalSalesHeader);
end;
/// <summary>
/// Calculates the document totals for all sales lines.
/// </summary>
procedure CalculateTotals()
begin
OnBeforeCalculateTotals(TotalSalesLine, SuppressTotals);
if SuppressTotals then
exit;
DocumentTotals.SalesCheckIfDocumentChanged(Rec, xRec);
DocumentTotals.CalculateSalesSubPageTotals(TotalSalesHeader, TotalSalesLine, VATAmount, InvoiceDiscountAmount, InvoiceDiscountPct);
DocumentTotals.RefreshSalesLine(Rec);
end;
/// <summary>
/// Performs an incremental update of document totals based on line changes.
/// </summary>
procedure DeltaUpdateTotals()
var
IsHandled: Boolean;
begin
if SuppressTotals then
exit;
IsHandled := false;
OnBeforeDeltaUpdateTotals(Rec, xRec, IsHandled);
if IsHandled then
exit;
DocumentTotals.SalesDeltaUpdateTotals(Rec, xRec, TotalSalesLine, VATAmount, InvoiceDiscountAmount, InvoiceDiscountPct);
if Rec."Line Amount" <> xRec."Line Amount" then
Rec.SendLineInvoiceDiscountResetNotification();
end;
/// <summary>
/// Forces a recalculation of document totals on the next update.
/// </summary>
procedure ForceTotalsCalculation()
begin
DocumentTotals.SalesDocTotalsNotUpToDate();
end;
/// <summary>
/// Redistributes invoice discount amounts across lines after validation.
/// </summary>
procedure RedistributeTotalsOnAfterValidate()
var
SalesHeader: Record "Sales Header";
begin
if SuppressTotals then
exit;
CurrPage.SaveRecord();
SalesHeader.Get(Rec."Document Type", Rec."Document No.");
DocumentTotals.SalesRedistributeInvoiceDiscountAmounts(Rec, VATAmount, TotalSalesLine);
CurrPage.Update(false);
end;
/// <summary>
/// Updates the type text display based on the current line type.
/// </summary>
procedure UpdateTypeText()
var
RecRef: RecordRef;
begin
OnBeforeUpdateTypeText(Rec);
RecRef.GetTable(Rec);
TypeAsText := TempOptionLookupBuffer.FormatOption(RecRef.Field(Rec.FieldNo(Type)));
end;
/// <summary>
/// Sets the style for item charge fields based on assignment status.
/// </summary>
procedure SetItemChargeFieldsStyle()
begin
ItemChargeStyleExpression := '';
if Rec.AssignedItemCharge() then
ItemChargeStyleExpression := 'Unfavorable';
end;
local procedure SetDimensionsVisibility()
var
DimMgt: Codeunit DimensionManagement;
begin
DimVisible1 := false;
DimVisible2 := false;
DimVisible3 := false;
DimVisible4 := false;
DimVisible5 := false;
DimVisible6 := false;
DimVisible7 := false;
DimVisible8 := false;
DimMgt.UseShortcutDims(
DimVisible1, DimVisible2, DimVisible3, DimVisible4, DimVisible5, DimVisible6, DimVisible7, DimVisible8);
Clear(DimMgt);
OnAfterSetDimensionsVisibility();
end;
local procedure SetItemReferenceVisibility()
var
ItemReference: Record "Item Reference";
begin
ItemReferenceVisible := not ItemReference.IsEmpty();
end;
local procedure ValidateShortcutDimension(DimIndex: Integer)
var
AssembleToOrderLink: Record "Assemble-to-Order Link";
begin
Rec.ValidateShortcutDimCode(DimIndex, ShortcutDimCode[DimIndex]);
AssembleToOrderLink.UpdateAsmDimFromSalesLine(Rec);
OnAfterValidateShortcutDimCode(Rec, ShortcutDimCode, DimIndex);
end;
local procedure SetDefaultType()
var
IsHandled: Boolean;
begin
IsHandled := false;
OnBeforeSetDefaultType(Rec, xRec, IsHandled);
if IsHandled then
exit;
if xRec."Document No." = '' then
Rec.Type := Rec.GetDefaultLineType();
end;
[IntegrationEvent(true, false)]
local procedure OnAfterNoOnAfterValidate(var SalesLine: Record "Sales Line"; xSalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(true, false)]
local procedure OnAfterQuantityOnAfterValidate(var SalesLine: Record "Sales Line"; xSalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(false, false)]
local procedure OnAfterUpdateEditableOnRow(SalesLine: Record "Sales Line"; var IsCommentLine: Boolean; var IsBlankNumber: Boolean);
begin
end;
[IntegrationEvent(true, false)]
local procedure OnAfterValidateDescription(var SalesLine: Record "Sales Line"; xSalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(false, false)]
local procedure OnAfterValidateShortcutDimCode(var SalesLine: Record "Sales Line"; var ShortcutDimCode: array[8] of Code[20]; DimIndex: Integer)
begin
end;
[IntegrationEvent(false, false)]
local procedure OnBeforeInsertExtendedText(var SalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(true, false)]
local procedure OnBeforeNoOnAfterValidate(var SalesLine: Record "Sales Line"; xSalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(false, false)]
local procedure OnBeforeUpdateTypeText(var SalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(false, false)]
local procedure OnItemReferenceNoOnLookup(var SalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(true, false)]
local procedure OnDeleteRecordOnBeforeSalesLineReserveDeleteLine(var SalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(true, false)]
local procedure OnQuantityOnAfterValidateOnBeforeDeltaUpdateTotals(var SalesLine: Record "Sales Line"; var xSalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(false, false)]
local procedure OnNewRecordOnAfterInitType(var SalesLine: Record "Sales Line"; xSalesLine: Record "Sales Line"; BelowxRec: Boolean)
begin
end;
[IntegrationEvent(false, false)]
local procedure OnBeforeCalculateTotals(var TotalSalesLine: Record "Sales Line"; SuppressTotals: Boolean)
begin
end;
[IntegrationEvent(false, false)]
local procedure OnBeforeSetDefaultType(var SalesLine: Record "Sales Line"; var xSalesLine: Record "Sales Line"; var IsHandled: Boolean)
begin
end;
[IntegrationEvent(true, false)]
local procedure OnBeforeSetOpenPage()
begin
end;
[IntegrationEvent(true, false)]
local procedure OnAfterSetDimensionsVisibility();
begin
end;
[IntegrationEvent(true, false)]
local procedure OnAfterShowNonstockItems(var SalesLine: Record "Sales Line")
begin
end;
[IntegrationEvent(true, false)]
local procedure OnBeforeDeltaUpdateTotals(var SalesLine: Record "Sales Line"; xSalesLine: Record "Sales Line"; var IsHandled: Boolean)
begin
end;
[IntegrationEvent(true, false)]
local procedure OnUnitofMeasureCodeOnAfterValidateOnBeforeDeltaUpdateTotals(var SalesLine: Record "Sales Line"; xSalesLine: Record "Sales Line")
begin
end;
}