Page 99000829 Firm Planned Prod. Order
- App
- Base Application
- Namespace
- Microsoft.Manufacturing.Document
- Versions
- 17-28
- Source table
- 5405
Versions171819202122232425262728
Source29
Source in 29
src/Layers/W1/BaseApp/Manufacturing/Document/FirmPlannedProdOrder.Page.al527 lines, Copyright (c) Microsoft Corporation. MIT
// ------------------------------------------------------------------------------------------------
// Copyright (c) Microsoft Corporation. All rights reserved.
// Licensed under the MIT License. See License.txt in the project root for license information.
// ------------------------------------------------------------------------------------------------
namespace Microsoft.Manufacturing.Document;
using Microsoft.Finance.Dimension;
using Microsoft.Foundation.Attachment;
using Microsoft.Inventory.Item;
using Microsoft.Inventory.Requisition;
using Microsoft.Manufacturing.Reports;
page 99000829 "Firm Planned Prod. Order"
{
Caption = 'Firm Planned Prod. Order';
PageType = Document;
SourceTable = "Production Order";
SourceTableView = where(Status = const("Firm Planned"));
layout
{
area(content)
{
group(General)
{
Caption = 'General';
field("No."; Rec."No.")
{
ApplicationArea = Manufacturing;
Importance = Promoted;
Lookup = false;
trigger OnAssistEdit()
begin
if Rec.AssistEdit(xRec) then
CurrPage.Update();
end;
}
field(Description; Rec.Description)
{
ApplicationArea = Manufacturing;
Importance = Promoted;
}
field("Description 2"; Rec."Description 2")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies an additional part of the production order description.';
}
field("Source Type"; Rec."Source Type")
{
ApplicationArea = Manufacturing;
trigger OnValidate()
begin
if xRec."Source Type" <> Rec."Source Type" then
Rec."Source No." := '';
end;
}
field("Source No."; Rec."Source No.")
{
ApplicationArea = Manufacturing;
ToolTip = 'Specifies the item number or number of the source document that the entry originates from.';
trigger OnValidate()
var
Item: Record "Item";
begin
if Rec."Variant Code" = '' then
VariantCodeMandatory := Item.IsVariantMandatory(Rec."Source Type" = Rec."Source Type"::Item, Rec."Source No.");
end;
}
field("Variant Code"; Rec."Variant Code")
{
ApplicationArea = Manufacturing;
Visible = false;
ShowMandatory = VariantCodeMandatory;
trigger OnValidate()
var
Item: Record "Item";
begin
if Rec."Variant Code" = '' then
VariantCodeMandatory := Item.IsVariantMandatory(Rec."Source Type" = Rec."Source Type"::Item, Rec."Source No.");
end;
}
field("Search Description"; Rec."Search Description")
{
ApplicationArea = Manufacturing;
}
field(Quantity; Rec.Quantity)
{
ApplicationArea = Manufacturing;
Importance = Promoted;
}
field("Due Date"; Rec."Due Date")
{
ApplicationArea = Manufacturing;
trigger OnValidate()
begin
CurrPage.Update(false);
end;
}
field("Assigned User ID"; Rec."Assigned User ID")
{
ApplicationArea = Manufacturing;
}
field("Last Date Modified"; Rec."Last Date Modified")
{
ApplicationArea = Manufacturing;
}
field("Manual Scheduling"; Rec."Manual Scheduling")
{
ApplicationArea = Manufacturing;
Importance = Additional;
}
}
part(ProdOrderLines; "Firm Planned Prod. Order Lines")
{
ApplicationArea = Manufacturing;
SubPageLink = "Prod. Order No." = field("No.");
UpdatePropagation = Both;
}
group(Schedule)
{
Caption = 'Schedule';
field("Starting Date-Time"; Rec."Starting Date-Time")
{
ApplicationArea = Manufacturing;
Importance = Promoted;
trigger OnValidate()
begin
CurrPage.Update(true);
end;
}
field("Ending Date-Time"; Rec."Ending Date-Time")
{
ApplicationArea = Manufacturing;
Importance = Promoted;
trigger OnValidate()
begin
CurrPage.Update(true);
end;
}
}
group(Posting)
{
Caption = 'Posting';
field("Inventory Posting Group"; Rec."Inventory Posting Group")
{
ApplicationArea = Manufacturing;
Importance = Promoted;
}
field("Gen. Prod. Posting Group"; Rec."Gen. Prod. Posting Group")
{
ApplicationArea = Manufacturing;
}
field("Gen. Bus. Posting Group"; Rec."Gen. Bus. Posting Group")
{
ApplicationArea = Manufacturing;
}
field("Shortcut Dimension 1 Code"; Rec."Shortcut Dimension 1 Code")
{
ApplicationArea = Dimensions;
trigger OnValidate()
begin
ShortcutDimension1CodeOnAfterV();
end;
}
field("Shortcut Dimension 2 Code"; Rec."Shortcut Dimension 2 Code")
{
ApplicationArea = Dimensions;
trigger OnValidate()
begin
ShortcutDimension2CodeOnAfterV();
end;
}
field("Location Code"; Rec."Location Code")
{
ApplicationArea = Location;
Importance = Promoted;
}
field("Bin Code"; Rec."Bin Code")
{
ApplicationArea = Warehouse;
Importance = Promoted;
}
}
}
area(factboxes)
{
part("Attached Documents List"; "Doc. Attachment List Factbox")
{
ApplicationArea = Manufacturing;
Caption = 'Documents';
UpdatePropagation = Both;
SubPageLink = "Table ID" = const(Database::"Production Order"),
"Document Type" = const("Firm Planned Production Order"),
"No." = field("No.");
}
systempart(Control1900383207; Links)
{
ApplicationArea = RecordLinks;
Visible = false;
}
systempart(Control1905767507; Notes)
{
ApplicationArea = Notes;
Visible = true;
}
}
}
actions
{
area(navigation)
{
group("O&rder")
{
Caption = 'O&rder';
Image = "Order";
action("Co&mments")
{
ApplicationArea = Manufacturing;
Caption = 'Co&mments';
Image = ViewComments;
RunObject = Page "Prod. Order Comment Sheet";
RunPageLink = Status = field(Status),
"Prod. Order No." = field("No.");
ToolTip = 'View or add comments for the record.';
}
action(Dimensions)
{
AccessByPermission = TableData Dimension = R;
ApplicationArea = Dimensions;
Caption = 'Dimensions';
Image = Dimensions;
ShortCutKey = 'Alt+D';
ToolTip = 'View or edit dimensions, such as area, project, or department, that you can assign to sales and purchase documents to distribute costs and analyze transaction history.';
trigger OnAction()
begin
Rec.ShowDocDim();
CurrPage.SaveRecord();
end;
}
action(Statistics)
{
ApplicationArea = Manufacturing;
Caption = 'Statistics';
Image = Statistics;
RunObject = Page "Production Order Statistics";
RunPageLink = Status = field(Status),
"No." = field("No."),
"Date Filter" = field("Date Filter");
ShortCutKey = 'F7';
ToolTip = 'View statistical information, such as the value of posted entries, for the record.';
}
action("Plannin&g")
{
ApplicationArea = Planning;
Caption = 'Plannin&g';
Image = Planning;
ToolTip = 'Plan supply orders for the production order order by order.';
trigger OnAction()
var
OrderPlanning: Page "Order Planning";
begin
OrderPlanning.SetProdOrderDemand(Rec.Status.AsInteger(), Rec."No.");
OrderPlanning.RunModal();
end;
}
action(DocAttach)
{
ApplicationArea = Manufacturing;
Caption = 'Attachments';
Image = Attach;
ToolTip = 'Add a file as an attachment. You can attach images as well as documents.';
trigger OnAction()
var
DocumentAttachmentDetails: Page "Document Attachment Details";
RecRef: RecordRef;
begin
RecRef.GetTable(Rec);
DocumentAttachmentDetails.OpenForRecRef(RecRef);
DocumentAttachmentDetails.RunModal();
end;
}
}
}
area(processing)
{
group("F&unctions")
{
Caption = 'F&unctions';
Image = "Action";
action("Re&fresh Production Order")
{
ApplicationArea = Manufacturing;
Caption = 'Re&fresh Production Order';
Ellipsis = true;
Image = Refresh;
ToolTip = 'Calculate changes made to the production order header without involving production BOM levels. The function calculates and initiates the values of the component lines and routing lines based on the master data defined in the assigned production BOM and routing, according to the order quantity and due date on the production order''s header.';
trigger OnAction()
var
ProdOrder: Record "Production Order";
begin
ProdOrder.SetRange(Status, Rec.Status);
ProdOrder.SetRange("No.", Rec."No.");
REPORT.RunModal(REPORT::"Refresh Production Order", true, true, ProdOrder);
end;
}
action("Re&plan")
{
ApplicationArea = Planning;
Caption = 'Re&plan';
Ellipsis = true;
Image = Replan;
ToolTip = 'Calculate changes made to components and routings lines including items on lower production BOM levels for which it may generate new production orders.';
trigger OnAction()
var
ProdOrder: Record "Production Order";
begin
ProdOrder.SetRange(Status, Rec.Status);
ProdOrder.SetRange("No.", Rec."No.");
REPORT.RunModal(REPORT::"Replan Production Order", true, true, ProdOrder);
end;
}
action("Change &Status")
{
ApplicationArea = Manufacturing;
Caption = 'Change &Status';
Ellipsis = true;
Image = ChangeStatus;
ToolTip = 'Change the production order to another status, such as Released.';
trigger OnAction()
begin
CurrPage.Update();
CODEUNIT.Run(CODEUNIT::"Prod. Order Status Management", Rec);
end;
}
action("&Update Unit Cost")
{
ApplicationArea = Manufacturing;
Caption = '&Update Unit Cost';
Ellipsis = true;
Image = UpdateUnitCost;
ToolTip = 'Update the cost of the parent item per changes to the production BOM or routing.';
trigger OnAction()
var
ProdOrder: Record "Production Order";
begin
ProdOrder.SetRange(Status, Rec.Status);
ProdOrder.SetRange("No.", Rec."No.");
REPORT.RunModal(REPORT::"Update Unit Cost", true, true, ProdOrder);
end;
}
action("C&opy Prod. Order Document")
{
ApplicationArea = Manufacturing;
Caption = 'C&opy Prod. Order Document';
Ellipsis = true;
Image = CopyDocument;
ToolTip = 'Copy information from an existing production order record to a new one. This can be done regardless of the status type of the production order. You can, for example, copy from a released production order to a new planned production order. Note that before you start to copy, you have to create the new record.';
trigger OnAction()
begin
CopyProdOrderDoc.SetProdOrder(Rec);
CopyProdOrderDoc.RunModal();
Clear(CopyProdOrderDoc);
end;
}
}
group("&Print")
{
Caption = '&Print';
Image = Print;
action("Job Card")
{
ApplicationArea = Manufacturing;
Caption = 'Job Card';
Ellipsis = true;
Image = "Report";
ToolTip = 'View a list of the work in progress of a production order. Output, scrapped quantity, and production lead time are shown depending on the operation.';
trigger OnAction()
begin
ManuPrintReport.PrintProductionOrder(Rec, 0);
end;
}
action("Mat. &Requisition")
{
ApplicationArea = Manufacturing;
Caption = 'Mat. &Requisition';
Ellipsis = true;
Image = "Report";
ToolTip = 'View a list of material requirements per production order. The report shows you the status of the production order, the quantity of end items and components with the corresponding required quantity. You can view the due date and location code of each component.';
trigger OnAction()
begin
ManuPrintReport.PrintProductionOrder(Rec, 1);
end;
}
action("Shortage List")
{
ApplicationArea = Manufacturing;
Caption = 'Shortage List';
Ellipsis = true;
Image = "Report";
ToolTip = 'View a list of the missing quantity per production order. The report shows how the inventory development is planned from today until the set day - for example whether orders are still open.';
trigger OnAction()
begin
ManuPrintReport.PrintProductionOrder(Rec, 2);
end;
}
}
}
area(reporting)
{
action("Subcontractor - Dispatch List")
{
ApplicationArea = Manufacturing;
Caption = 'Subcontractor - Dispatch List';
Image = "Report";
//The property 'PromotedCategory' can only be set if the property 'Promoted' is set to 'true'
//PromotedCategory = "Report";
RunObject = Report "Subcontractor - Dispatch List";
}
}
area(Promoted)
{
group(Category_Process)
{
Caption = 'Process', Comment = 'Generated from the PromotedActionCategories property index 1.';
actionref("Change &Status_Promoted"; "Change &Status")
{
}
actionref("Re&fresh Production Order_Promoted"; "Re&fresh Production Order")
{
}
actionref("Re&plan_Promoted"; "Re&plan")
{
}
}
group(Category_Print)
{
Caption = 'Print';
actionref("Shortage List_Promoted"; "Shortage List")
{
}
actionref("Job Card_Promoted"; "Job Card")
{
}
actionref("Mat. &Requisition_Promoted"; "Mat. &Requisition")
{
}
}
group(Category_Category4)
{
Caption = 'Order', Comment = 'Generated from the PromotedActionCategories property index 3.';
actionref(Dimensions_Promoted; Dimensions)
{
}
actionref(Statistics_Promoted; Statistics)
{
}
actionref("Co&mments_Promoted"; "Co&mments")
{
}
actionref(DocAttach_Promoted; DocAttach)
{
}
}
group(Category_Report)
{
Caption = 'Report', Comment = 'Generated from the PromotedActionCategories property index 2.';
}
}
}
trigger OnAfterGetRecord()
var
Item: Record Item;
begin
if Rec."Variant Code" = '' then
VariantCodeMandatory := Item.IsVariantMandatory(Rec."Source Type" = Rec."Source Type"::Item, Rec."Source No.");
end;
trigger OnInit()
begin
end;
trigger OnOpenPage()
begin
end;
var
CopyProdOrderDoc: Report "Copy Production Order Document";
ManuPrintReport: Codeunit "Manu. Print Report";
VariantCodeMandatory: Boolean;
local procedure ShortcutDimension1CodeOnAfterV()
begin
CurrPage.ProdOrderLines.PAGE.UpdateForm(true);
end;
local procedure ShortcutDimension2CodeOnAfterV()
begin
CurrPage.ProdOrderLines.PAGE.UpdateForm(true);
end;
}