Analyze MCP server tool calls telemetry

APPLIES TO: Business Central 2026 release wave 1, version 28.0, and later

Model Context Protocol (MCP) server telemetry gathers data about calls that external MCP hosts make to tools exposed by Business Central MCP server configurations. This telemetry helps you understand how external clients use Business Central through MCP.

Learn more in Configure Business Central MCP Server.

MCP server tool called

Occurs when Business Central processes a tool call from an MCP host.

General dimensions

DimensionDescription or value
messageMCP Server tool called: '{toolName}'
user_IdThe user telemetry ID for the user. From the user card, you can use user_Id to identify the user who triggered this telemetry event. Learn more in Assign a telemetry ID to users.

Custom dimensions

DimensionDescription or value
aadTenantIdSpecifies the Microsoft Entra tenant ID used for Microsoft Entra authentication. For on-premises, if you aren't using Microsoft Entra authentication, this value is common.
companyNameThe current company name.
environmentNameSpecifies the name of the tenant environment. Learn more in Managing Environments.
environmentTypeSpecifies the environment type for the tenant, such as Production or Sandbox. Learn more in Environment Types.
eventIdRT0054
configurationNameSpecifies the name of the MCP configuration that was used for the tool call.
configurationSystemIdSpecifies the system ID (GUID) of the MCP configuration record.
toolNameSpecifies the name of the MCP tool that was called.
dynamicToolNameSpecifies the action name for dynamic MCP tools. This dimension is populated when using dynamic tool configurations.
clientNameSpecifies the name of the MCP host that initiated the tool call.
authAppIdSpecifies the authenticated application ID from the security token.
resultSpecifies the result of the operation. Possible values are Success or Failure.
totalTimeSpecifies the total time the operation ran for.
serverExecutionTimeSpecifies the amount of time the operation took on server. The time has the format hh:mm:ss.sssssss.
toolInvocationResultSpecifies the result of the MCP tool invocation. Possible values are Success or Failure. This dimension can be absent if an exception prevents the tool call from returning a result.
toolInvocationFailureReasonSpecifies the reason for the tool invocation failure. This dimension is only populated when toolInvocationResult is Failure.

Sample KQL code

This KQL code can help you get started analyzing MCP Server tool calls:

traces
| where timestamp > ago(60d) // adjust as needed
| where customDimensions.eventId == 'RT0054'
| project timestamp
, aadTenantId = customDimensions.aadTenantId
, environmentName = customDimensions.environmentName
, environmentType = customDimensions.environmentType
, companyName = customDimensions.companyName
, configurationName = customDimensions.configurationName
, toolName = customDimensions.toolName
, dynamicToolName = customDimensions.dynamicToolName
, clientName = customDimensions.clientName
, toolInvocationResult = customDimensions.toolInvocationResult
, toolInvocationFailureReason = customDimensions.toolInvocationFailureReason
, totalTime = customDimensions.totalTime
, serverExecutionTime = customDimensions.serverExecutionTime

Sample KQL code for failed tool invocations

This KQL code can help you analyze failed MCP Server tool calls:

traces
| where timestamp > ago(60d) // adjust as needed
| where customDimensions.eventId == 'RT0054'
| where customDimensions.toolInvocationResult == 'Failure'
| project timestamp
, aadTenantId = customDimensions.aadTenantId
, environmentName = customDimensions.environmentName
, environmentType = customDimensions.environmentType
, companyName = customDimensions.companyName
, configurationName = customDimensions.configurationName
, toolName = customDimensions.toolName
, clientName = customDimensions.clientName
, toolInvocationFailureReason = customDimensions.toolInvocationFailureReason
| summarize FailureCount = count() by tostring(toolName), tostring(toolInvocationFailureReason)
| order by FailureCount desc

Sample KQL code for tool usage by configuration

This KQL code can help you understand which MCP configurations and tools are being used most frequently:

traces
| where timestamp > ago(30d) // adjust as needed
| where customDimensions.eventId == 'RT0054'
| summarize
    TotalCalls = count()
  , SuccessfulCalls = countif(customDimensions.toolInvocationResult == 'Success')
  , FailedCalls = countif(customDimensions.toolInvocationResult == 'Failure')
  , AvgServerExecutionTimeInMs = avg(toreal(totimespan(customDimensions.serverExecutionTime)) / 10000)
  by
    ConfigurationName = tostring(customDimensions.configurationName)
  , ToolName = tostring(customDimensions.toolName)
  , ClientName = tostring(customDimensions.clientName)
| extend SuccessRate = round(100.0 * SuccessfulCalls / TotalCalls, 2)
| order by TotalCalls desc

To learn more about how to set up alerting on Business Central telemetry, see Alert on Telemetry.

Model Context Protocol (MCP) in Business Central overview
Configure Business Central MCP Server
Connect to Business Central MCP Server with Visual Studio Code
Connect to Business Central MCP server with non-Microsoft clients
Business Central Admin Center API MCP server
Monitoring and Analyzing Telemetry
Enable Sending Telemetry to Application Insights
Alert on Telemetry